I have a properties file that contain values in the format of
variable_one = value_one
variable_two = value_two
.
.
.
.
. and so onFor /F "tokens=1* delims==" "variable_one", "variable_two" IN (testing.properties) DO (
IF "variable_one"=="variable_one" set local_variable_one=%%B
IF "variable_two"=="variable_two" set local_variable_two=%%C
)
echo "%local_variable%"
pauseDoes the properies file really contain the spaces between the = ?
Something like this will read all the properies and display their values only:
@echo off
for /f "tokens=2 delims== " %%i in (testing.properties) do echo %%i
pause
where this will display the property name as well as the value:
@echo off
for /f "tokens=1,* delims== " %%i in (testing.properties) do echo Property: %%i Value: %%j
pause
if you really want to set the properties as variables (to use as readable variables).
@echo off
setlocal enabledelayedexpansion
for /f "tokens=1,* delims== " %%i in (testing.properties) do (
set property=%%i
set value=%%j
echo !property! !value!
)
pause
Comparing values and then setting them is another task on its own. Here you are giving an example, so give a real example and we can work from there. For instance. We can set the property name value as the vaiable name without manually typing it:
@echo off
setlocal enabledelayedexpansion
for /f "tokens=1,* delims== " %%i in (testing.properties) do (
set %%i=%%j
echo Property: %%i has Value: !%%i!
)
pause
or even add a something to the string:
@echo off
setlocal enabledelayedexpansion
for /f "tokens=1,* delims== " %%i in (testing.properties) do (
set local_%%i=%%j
echo Property: %%i has value !local_%%i! set as Variable local_%%i
)
pause
Finally, giving your variables unique names will depend on some search criteria, you can probably use identifiers from your properties. For instance do a findstr on part of your property, or simply matching a numeric value or anything unique in a property.
for /F "usebackq tokens=1* delims== " %%I in ("testing.properties") do set "%%I=%%J". No variable name (line) should start with;because offorignores those lines. On no spaces around equal sign the FOR loop would be:for /F "usebackq delims= eol=" %%I in ("testing.properties") do set "%%I". See also Why is no string output with 'echo %var%' after using 'set var = text' on command line?