add multiple numbers in batch

Question

i try to add two numbers received from a file.
But it shows only the last value of sum. Thx for the help!

@FOR /F "eol=; tokens=1-3 delims=, " %%i IN (test.txt) DO (  
   set m=%%j   
   set n=%%k  
   set /a sum=%m%+%n%  
   echo sum = %sum%  
   )

and in the test.txt i have

alex 4 5  
john 6 7

and i want to see

sum=9  
sum=13

it only shows

sum=13  
sum=13

You failed to note one tiny detail: On first run it will only show sum = . It's not exactl y the last value your loop shows but instead the one from before the loop. — Joey
– Joey, Commented Apr 7, 2011 at 14:00

jeb · Accepted Answer · 2011-04-07 12:51:39Z

2

The problem is the percent expanding in the line set /a sum=%m%+%n% and echo sum = %sum%.
These are expanded before the FOR-loop is executed.

Therefore you got the result of the "global" set of sum.

It's better to use the delayed expansion, as then all variables enclosed with ! are expanded at runtime not parsetime

@echo off
setlocal EnableDelayedExpansion
FOR /F "eol=; tokens=1-3 delims=, " %%i IN (test.txt) DO (  
   set m=%%j   
   set n=%%k  
   set /a sum=m+n
   echo sum = !sum!
)

answered Apr 7, 2011 at 12:51

jeb

83.2k20 gold badges181 silver badges237 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Andriy M Over a year ago

@Alex: Note also that the variables m and n are referenced without using either % or ! around their names on the line that calculates sum. This special way of referencing is allowed in SET /A command and it has the effect of delayed expansion (i.e. it works as if you referenced them like this: set /a sum=!m!+!n!).

Collectives™ on Stack Overflow

add multiple numbers in batch

1 Answer 1

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related