gnuplot: Create multiple boxplots from different data files on the same output

Question

I have a set of files that contain data that I want to produce a set of box plots for in order to compare them. I can get the data into gnuplot, but I don't know the correct format to separate each file into its own plot.

I have tried reading all the required files into a variable, which does work, however when the plot is produced, all the boxplots are on top of each other. I need to get gnuplot to index each plot along one space for each new data file.

For example, this produces the output with overlaying plots:

FILES = system("ls -1 /path/to/files/*")

plot    for [data in FILES] data using (1):($4)  with boxplot notitle

I know the X position is being stated explicitly there with the (1), but I'm not sure what to replace it with to get the position to move for each plot. This isn't a problem with other chart types, since they don't have the same field locating them.

theozh · Accepted Answer · 2019-07-11 10:50:19Z

2

You can try the following. You can access the file in your file list by index via word(FILES,i). Check help word and help words. The code below assumes that you have some datafiles Data0*.dat in your directory. Maybe there is a smarter/shorter way to implement the xtic labels.

Code:

### boxplots from a list of files
reset session

# get a list of files (Windows)
FILES = system('dir /B "C:\Data\Data0*.dat"')

# set tics as filenames
set xtics ()    # remove xtics
set yrange [-2:27]
do for [i=1:words(FILES)] {
    set xtics add (word(FILES,i) i) rotate by 45 right
}

plot for [i=1:words(FILES)] word(FILES,i) u (i):2 w boxplot notitle
### end of code

Result:

edited Jul 11, 2019 at 10:50

answered Jul 11, 2019 at 8:45

theozh

27.1k6 gold badges42 silver badges92 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

caius Over a year ago

Thank you this works perfectly. I had managed to get something that worked by using a bash script to concatenate the data files into blocks and using the index function in gnuplot. This solution is neater however, as it doesn't require a wrapper script or the creation of a temporary file.

Collectives™ on Stack Overflow

gnuplot: Create multiple boxplots from different data files on the same output

1 Answer 1

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related