Convert table like text into separate values with column names using Shell scripting

Could you please try following.

awk '
BEGIN{
  FS=SUBSEP=OFS=","
}
FNR==1{
  split($0,header,", ")
  next
}
{
  a[$1,$2,$3]=(a[$1,$2,$3]?a[$1,$2,$3]":":"")$4
}
END{
  for(i in a){
    val=i OFS a[i]
    num=split(val,array,",")
    for(o=1;o<=num;o++){
      print header[o],array[o]
    }
    delete array
  }
}
' Input_file

Explanation: Adding a detailed explanation for above code.

awk '                                                     ##Starting awk program from here.
BEGIN{                                                    ##Starting BEGIN section here.
  FS=SUBSEP=OFS=","                                       ##Setting FS, OFS and SUBSEP as comma here.
}                                                         ##Closing BEGIN BLOCK for this awk code.
FNR==1{                                                   ##Checking condition if this is first line then do following.
  split($0,header,",")                                    ##Splitting line into an array named header whose delimiter is comma here.
  next                                                    ##next will skip all further statements from here.
}                                                         ##Closing BLOCK for FNR==1 condition here.
{
  a[$1,$2,$3]=(a[$1,$2,$3]?a[$1,$2,$3]":":"")$4           ##Creating an array named a whose index is $1,$2,$3 and value is $4 with concatenating each line its own value in it.
}
END{                                                      ##Starting END block for this awk code here.
  for(i in a){                                            ##Traversing through array a all elements.
    val=i OFS a[i]                                        ##Creating a variable val and its value is variable i(index of array a) OFS and array a value here.
    num=split(val,array,",")                              ##Splitting variable val to array named array whose delimiter is comma here.
    for(o=1;o<=num;o++){                                  ##Starting a for loop from o=1 to till value of num.
      print header[o],array[o]                            ##Printing header array with index of o and array with index of o here.
    }
    delete array                                          ##Deleting array here, to avoid confusions, since each cycle new array will be created.
  }
}
'  Input_file                                             ##Mentioning Input_file name here.