Awk column with pattern array

Question

Is it possible to do this but use an actual array of strings where it says "array"

array=(cat
dog
mouse
fish
...)

awk -F "," '{ if ( $5!="array" ) { print $0; } }' file

I would like to use spaces in some of the strings in my array. I would also like to be able to match partial matches, so "snow" in my array would match "snowman" It should be case sensitive.

Example csv

s,dog,34
3,cat,4
1,african elephant,gd
A,African Elephant,33
H,snowman,8
8,indian elephant,3k
7,Fish,94
...

Example array

snow
dog
african elephant

Expected output

s,dog,34
H,snowman,8
1,african elephant,gd

Cyrus posted this which works well, but it doesn't allow spaces in the array strings and wont match partial matches.

echo "${array[@]}" | awk 'FNR==NR{len=split($0,a," "); next} {for(i=1;i<=len;i++) {if(a[i]==$2){next}} print}' FS=',' - file

Ed Morton · Accepted Answer · 2020-02-05 14:24:27Z

2

The brief approach using a single regexp for all array contents:

$ array=('snow' 'dog' 'african elephant')
$ printf '%s\n' "${array[@]}" | awk -F, 'NR==FNR{r=r s $0; s="|"; next} $2~r' - example.csv
s,dog,34
1,african elephant,gd
H,snowman,8

Or if you prefer string comparisons:

$ cat tst.sh
#!/bin/env bash

array=('snow' 'dog' 'african elephant')

printf '%s\n' "${array[@]}" |
awk -F',' '
    NR==FNR {
        array[$0]
        next
    }
    {
        for (val in array) {
            if ( index($2,val) ) {      # or $2 ~ val for a regexp match
                print
                next
            }
        }
    }
' - example.csv

$ ./tst.sh
s,dog,34
1,african elephant,gd
H,snowman,8

edited Feb 5, 2020 at 14:24

answered Feb 5, 2020 at 14:08

Ed Morton

209k18 gold badges90 silver badges212 bronze badges

Sign up to request clarification or add additional context in comments.

3 Comments

Chris Over a year ago

Thats perfect thanks. How could I do the reverse? Print if there is no match.

Ed Morton Over a year ago

You're welcome. I'm sure you could figure that out with a couple minutes of thought (hint: the "not" symbol is !) but if you can't then ask a new question as everyone hates chameleon questions.

Chris Over a year ago

I think it needs to go in this line but not sure how. if ( index($3,val) )

Cyrus · Accepted Answer · 2020-02-04 20:11:53Z

1

This prints no line from csv file which contains an element from array in column 5:

echo "${array[@]}" | awk 'FNR==NR{len=split($0,a," "); next} {for(i=1;i<=len;i++) {if(a[i]==$5){next}} print}' FS=',' - file

answered Feb 4, 2020 at 20:11

Cyrus

90.2k15 gold badges112 silver badges173 bronze badges

1 Comment

Chris Over a year ago

Is it possible to have strings with spaces in my array? What about partial matching? So "snow" in my array would match "snowman". Should have mentioned these in the OP.

Collectives™ on Stack Overflow

Awk column with pattern array

2 Answers 2

3 Comments

1 Comment

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

3 Comments

1 Comment

Your Answer

Sign up or log in

Post as a guest

Linked

Related