Find, count and index the duplicate items in array

Question

I have an array which has some duplicate values.
I have to count the number of each duplicate items and their index.
Print such as:

Index of b: 1
Index of b: 4
Index of c: 2
Index of c: 3
Index of c: 5
Index of e: 7
Index of e: 8

Total duplicate b: 2
Total duplicate c: 3
Total duplicate e: 2

In my code I'm able to find only duplicate values.

Dim list As New List(Of String) From {"a", "b", "c", "c", "b", "c", "d", "e", "e"}
Dim duplicates = list.GroupBy(Function(x) x).Where(Function(x) x.Count > 1).Select(Function(x) x.Key)

For Each i As String In list.ToArray
    If duplicates.Contains(i) Then
        Debug.WriteLine("Duplicate Element: " & i & "Index:  " & list.IndexOf(i))
    End If
Next

Which gives output:

Duplicate Element: bIndex:  1
Duplicate Element: cIndex:  2
Duplicate Element: cIndex:  2
Duplicate Element: bIndex:  1
Duplicate Element: cIndex:  2
Duplicate Element: eIndex:  7
Duplicate Element: eIndex:  7

Jimi · Accepted Answer · 2020-02-26 19:27:35Z

2

You already have an answer, but I propose a slightly different method anyway, it might come in handy after. This uses the same LINQ methods you already have.

The LINQ's query creates an object that contains the value and position of all strings in the elements List, groups the values then selects the groups that contain more than one item and finally orders the groups by their Key value.

Dim elements = {"a", "b", "c", "c", "b", "c", "d", "e", "e"}.ToList()
Dim duplicates = elements.Select(Function(elm, i) New With {.Value = elm, .Index = i}).
                          GroupBy(Function(obj) obj.Value).
                          Where(Function(grp) grp.Count() > 1).
                          OrderBy(Function(grp) grp.Key)

For Each group In duplicates
    For Each dupe In group
        Console.WriteLine($"Duplicate: {dupe.Value} Index = {dupe.Index}")
    Next
    Console.WriteLine($"Number of {group.Key} duplicates: {group.Count()}")
Next

This prints:

Duplicate: b Index = 1
Duplicate: b Index = 4
Number of b duplicates: 2

Duplicate: c Index = 2
Duplicate: c Index = 3
Duplicate: c Index = 5
Number of c duplicates: 3

Duplicate: e Index = 7
Duplicate: e Index = 8
Number of e duplicates: 2

edited Feb 26, 2020 at 19:27

answered Feb 26, 2020 at 18:20

Jimi

33.3k8 gold badges52 silver badges84 bronze badges

Sign up to request clarification or add additional context in comments.

3 Comments

djv Over a year ago

I was going to contribute too, then I realized my code did not differ from this answer at all. Ha!

Jimi Over a year ago

@djv There's a possible interesting alternative: since the source is a List<string>, you could use BinarySearch in a loop, using the result as the base index to search the next value. It would be much more efficient and even shorter.

djv Over a year ago

What do you think this is, a job interview? :)

dbasnett · Accepted Answer · 2020-02-26 19:04:38Z

1

An approach

    Dim list As New List(Of String) From {"a", "e", "e", "b", "c", "c", "b", "c", "d", "e"}
    Dim duplicates As IEnumerable(Of String) = list.Distinct
    duplicates = From s In duplicates
                  Where list.FindAll(Function(l) l = s).Count > 1
                  Select s

    For Each s As String In duplicates
        Dim ct As Integer = (From l In list Where l = s Select l).Count
        Debug.WriteLine(s)
        Debug.WriteLine("count:{0}", ct)
        Dim idx As IEnumerable(Of Integer)
        idx = From n In Enumerable.Range(0, list.Count)
              Where list(n) = s
              Select n Take ct

        Debug.WriteLine("Indexes")
        For Each n As Integer In idx
            Debug.Write(n.ToString)
            Debug.Write(" ")
        Next
        Debug.WriteLine("")
    Next

Output

e
count:3
Indexes
1 2 9 
b
count:2
Indexes
3 6 
c
count:3
Indexes
4 5 7

edited Feb 26, 2020 at 19:04

answered Feb 26, 2020 at 17:30

dbasnett

11.8k2 gold badges27 silver badges36 bronze badges

1 Comment

Nikesh Gupta Over a year ago

That's perfect! Thank You.

Collectives™ on Stack Overflow

Find, count and index the duplicate items in array

2 Answers 2

3 Comments

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

3 Comments

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related