How to put exception handled code in a Delphi exception handler?

try
  // <Normal code>
  raise Exception.Create('Original error');
except
  on E: Exception do
  try
    // <Attempt to mitigate the error>  // If successful will continue without an exception
    raise Exception.Create('Mitigation error'); 
  except
    raise E;  // Mitigation failed, raise original error
  end;
end;

Once you handle an exception, it will be destroyed at the end of the except block which handles it. However, you do raise E which propagates the exception beyond that block, and beyond the end of its life.

If you wish to re-raise an exception, and thus prolong its life beyond the block which handles it, then you need to use different syntax, unadorned raise. However, you cannot do that inside the nested except block since that would refer to the mitigation error. Instead you need to write raise in the outer except block:

procedure Foo;
var
  MitigationSucceeded: Boolean;
begin
  try
    // <Normal code>
    raise Exception.Create('Original error');
  except
    on E: Exception do
    begin
      try
        MitigationSucceeded := True;
        // <Attempt to mitigate the error>  // If successful will continue without an exception
        raise Exception.Create('Mitigation error');
      except
        // using raise here would refer to mitigation error ...
        MitigationSucceeded := False;
      end;

      if not MitigationSucceeded then
        // ... but used here it is the original error
        raise;
    end;
  end;
end;