Insert Multiple Rows with One insert statement and parameters

You don't loop through a DataTable to save data. You use a data adapter to save the lot in one go. I'll provide an example to demonstrate the principle and let you apply that principle to your specific scenario.

'Create and populate the DataTable.
Dim table As New DataTable

With table.Columns
    .Add("Name", GetType(String))
    .Add("Amount", GetType(Integer))
End With

With table.Rows
    .Add("One", 1)
    .Add("Two", 2)
    .Add("Three", 3)
End With

'Create the data adapter.
Using connection As New SqlConnection("connection string here"),
      command As New SqlCommand("INSERT INTO MyTable (Name, Amount) VALUES (@Name, @Amount)", connection),
      adapter As New SqlDataAdapter With {.InsertCommand = command}
    'Add parameters.
    With command.Parameters
        .Add("@Name", SqlDbType.VarChar, 50, "Name")
        .Add("@Amount", SqlDbType.Int, 0, "Amount")
    End With

    'Save data.
    adapter.Update(table)
End Using

You need to make sure that the RowState of each DataRow is Added in order for them to be inserted. If you have added the rows in code, as I have above, then they already will be. If you're populating the DataTable with a data adapter then you can set its AcceptChangesOnFill property to False to leave the rows in that state. Otherwise, you can call SetAdded on each row.

You might check here for more information.

The Using...End Using block assures that your connection and command are closed and disposed even if there is an error. If possible always list your field names in your sql statement. I had to guess at the names.

Add the parameters once outside the loop. Then just reset the values of the parameters on each iteration.

Sub bandingkan_data_tblpibconr()
    Dim dt3 = query.LoadAcces_tblpibconr
    Using cn As New NpgsqlConnection(ConStr),
            cmd As New NpgsqlCommand("insert into tblpibconr (Car, Reskd, Contno, Contukur, Conttipe) Values (@car, @reskd, @contno, @contukur, @conttipe);")
        With cmd.Parameters
            .Add("@car", NpgsqlTypes.NpgsqlDbType.Text)
            .Add("@reskd", NpgsqlTypes.NpgsqlDbType.Text)
            .Add("@contno", NpgsqlTypes.NpgsqlDbType.Text)
            .Add("@contukur", NpgsqlTypes.NpgsqlDbType.Text)
            .Add("@conttipe", NpgsqlTypes.NpgsqlDbType.Text)
        End With
        cn.Open()
        For Each row As DataRow In dt3.Rows
            cmd.Parameters("@car").Value = row("car").ToString
            cmd.Parameters("@reskd").Value = row("reskd").ToString
            cmd.Parameters("@contno").Value = row("contno").ToString
            cmd.Parameters("@contukur").Value = row("contukur").ToString
            cmd.Parameters("@conttipe").Value = row("conttipe").ToString
            cmd.ExecuteNonQuery()
        Next
    End Using
End Sub