Decimal to Binary Clojure

Question

I'm following this pseudo code to convert decimal to binary recursively.

findBinary(decimal)
   if (decimal == 0)
      binary = 0
   else
      binary = decimal % 2 + 10 * (findBinary(decimal / 2)

This is what I have tried:

(defn binary [n]
  (loop [res 0]
    (if (= n 0)
    res
    (recur (res (* (+ (mod n 2) 10) (binary (quot n 2)))) )
    )
  )
)

But I get this error :

ClassCastException java.lang.Long cannot be cast to clojure.lang.IFn  user/binary (form-init9002795692676588773.clj:6)

Any ideas how to fix the code to complete the task?

When I needed to convert a decimal to binary, I used strings, so it surprised me to see the decimal converted to binary using only numbers. Neat. — Aaron Bell
– Aaron Bell, Commented Mar 1, 2021 at 2:08

cfrick · Accepted Answer · 2021-03-02 12:08:18Z

8

I realize, that this is about the journey and not the result. But to have it mentioned: Long/toString can give you a string from a number with a wide variety of radixes.

(Long/toString 123 2)
; → "1111011"

edited Mar 2, 2021 at 12:08

answered Feb 28, 2021 at 10:52

cfrick

37.3k7 gold badges62 silver badges77 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Bob Jarvis - Слава Україні · Accepted Answer · 2021-02-28 04:33:40Z

4

Here's a slightly different approach which allows recur to be used:

(defn find-binary [d]
  (loop [ decimal  d
          digits   '() ]
    (if (= decimal 0)
      (Integer. (clojure.string/join (map str digits)))
      (recur (quot decimal 2) (conj digits (mod decimal 2))))))

In the loop we build up a collection of binary digits, adding each new digit at the beginning of the list so that we end up with the digits in the desired order left-to-right in the list. When the terminating condition is reached we convert the collection-of-digits to a collection-of-strings, join the collection of strings together into single string, and convert the string back to an integer.

answered Feb 28, 2021 at 4:33

Bob Jarvis - Слава Україні

50.2k10 gold badges81 silver badges119 bronze badges

Comments

jas · Accepted Answer · 2021-02-28 05:43:25Z

3

Your psuedo code can be expressed pretty directly in clojure:

(defn find-binary [decimal]
  (if (= decimal 0)
    0
    (+ (mod decimal 2) (* 10 (find-binary (quot decimal 2))))))

Examples:

user=> (find-binary 1)
1
user=> (find-binary 2)
10
user=> (find-binary 25)
11001
user=> (find-binary 255)
11111111

The error in your version is here:

  (recur (res (* (+ (mod n 2) 10) (binary (quot n 2))))

Specifically, the complaint is that you are trying to use res (which has the value 0) as a function.

To be honest, I'm not sure how to do this with loop-recur. When I try it complains about recur not being from the tail position. Perhaps another answer can enlighten us!

edited Feb 28, 2021 at 5:43

answered Feb 28, 2021 at 2:50

jas

10.9k2 gold badges33 silver badges45 bronze badges

Comments

Gwang-Jin Kim · Accepted Answer · 2021-03-02 20:59:51Z

Using recur:

;; returns a binary number string of the given decimal number
(defn find-binary [decimal]
  (loop [n decimal
         res ""]
    (if (= n 0)
        res
        (recur (quot n 2)
               (str (mod n 2) res)))))

But without loop:

(defn find-binary [decimal & {:keys [acc] :or {acc ""}}]
    (if (= decimal 0)
        acc
        (find-binary (quot decimal 2) :acc (str (mod decimal 2) acc))))

The original attempt was the following, but it can't go far in the size of decimal:

(defn find-binary [decimal]
  (loop [n decimal ;; number to be binarized
         res '()   ;; collector list
         pos 0]    ;; position of binary number
    (if (= n 0)
        (reduce #'+ res) ;; sum up collector list
        (recur (quot n 2)
               (cons (* (int (Math/pow 10 pos)) 
                        (mod n 2))
                     res)
               (+ 1 pos)))))

For large numbers use:

Collectives™ on Stack Overflow

Decimal to Binary Clojure

4 Answers 4

Comments

Comments

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

4 Answers 4

Comments

Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related