Batch Script Loop through Array with Variable Index

Question

Due to some operational needs, I am trying to write some simple batch script (hard code acceptable) which replace the filenames if it see some patterns, the replacement strings and the patterns are 1-1 mapping.

But I am stuck at the last step: For the Ren command, I could not access the arrays using variable counter. If I replace %counter% into integers like 2 or 3, the script works and can rename that specific file.

I am very new to batch script, may I know how can I access the array elements with variable index?

@ECHO OFF
Setlocal enabledelayedexpansion

Set "Pattern[0]=pat0"
Set "Pattern[1]=pat1"
...

Set "Replace[0]=rep0"
Set "Replace[1]=rep1"
...

Set /a counter = 0

For /r %%# in (*.pdf) Do (
    Set "File=%%~nx#"
    Ren "%%#" "!File:%Pattern[%counter%]%=%Replace[%counter%]%!"
    Set /a counter += 1
)

endlocal

Arrays, linked lists and other data structures in cmd.exe (batch) script — Aacini
– Aacini, Commented Jun 24, 2021 at 15:40

npocmaka · Accepted Answer · 2021-06-24 12:11:48Z

2

Try like this with an additional for loop:

@ECHO OFF
Setlocal enabledelayedexpansion

Set "Pattern[0]=pat0"
Set "Pattern[1]=pat1"


Set "Replace[0]=rep0"
Set "Replace[1]=rep1"

Set /a counter = 0

For /r %%# in (*.pdf) Do (
    Set "File=%%~nx#"
    
    For /f "tokens=1,2 delims=;" %%A in ("!Pattern[%counter%]!;!Replace[%counter%]!") do (
        echo Ren "%%#" "!File:%%A=%%B!"
    )
    
    Set /a counter += 1
)

endlocal

You can also try with additional subroutine or using CALL (see the Advanced usage : CALLing internal commands section and call set) but this should the best performing approach.

edited Jun 24, 2021 at 12:11

answered Jun 24, 2021 at 8:28

npocmaka

57.8k19 gold badges162 silver badges199 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

shole Over a year ago

Thanks for the reply! I tried it but it seems it always only execute the outer loop for one time. I tried to echo %counter% in outerloop and it only prints 0, never prints 1, 2 .....

npocmaka Over a year ago

@shole Ah. I see. But you figured it out :)

shole · Accepted Answer · 2021-06-25 04:28:09Z

1

Based on @npocmaka's reply, I have further add a simple loop and finally it works for my case:

For /r %%# in (*.pdf) Do (
    Set "File=%%~nx#"
    For /l %%c in (0,1,8) Do (
        For /f "tokens=1,2 delims=;" %%A in ("!Pattern[%%c]!;!Replace[%%c]!") Do (
            Ren "%%#" "!File:%%A=%%B!"
            
        )
    )
    
)

answered Jun 25, 2021 at 4:28

shole

4,1342 gold badges33 silver badges73 bronze badges

Collectives™ on Stack Overflow

Batch Script Loop through Array with Variable Index

2 Answers 2

2 Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

2 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related