E4X/AS3, get an array of text elements without looping

Question

this is part of an XML file I retrieve using AS3 E4X:

<links>
    <link>
      <label>Versions</label>
      <href>http://mylink1</href>
    </link>
    <link>
      <label>Configurations</label>
      <href>http://myLink2</href>
    </link>
</links>

I want to retrieve the values of labels, so I write:

document.links.link.label.text();

This returns VersionsConfigurations. I need this as Array ([Versions, Configurations]) but I would like not to use a loop. Is there any other way?

Sorry, I found one way, and I want to share it with you all. You can do this by writing document.links.link.label.text().toXMLString().slice("\n"). The method toXMLString() adds a useful (undocumented) "\n" and you can use it to split the string. Of course this results in an XML string — user840248
– user840248, Commented Jul 25, 2011 at 9:08
You can post answers to your own questions, although it will make you wait 2 days before you can accept you own answer. — shanethehat
– shanethehat, Commented Jul 25, 2011 at 9:09

Michael Antipin · Accepted Answer · 2011-07-26 21:07:27Z

1

Well, this is a "don't try this at home" solution, but here you are. :)

You can use E4X search expression to do whatever you want to nodes of an XMLList.

This works as follows: someXMLList.(expression), where expression is any AS3 code that can access each node's properties and methods with no need of qualifying their names. For instance, you could do the following:

yourXML.descendants("label").(trace("label text: ", text()));

Note that I'm using text() here with no access . operations. Actually this will return an new XMLList for all nodes, where expression evaluated to true. Since trace() returns void, the resulting list will be empty. Internally there is of course a loop through all nodes of XMLLIst that is created by calling descendants() (or using .. operator).

You can construct your array the same way.

var doc:XML = 
<links>
    <link>
      <label>Versions</label>
      <href>http://mylink1</href>
    </link>
    <link>
      <label>Configurations</label>
      <href>http://myLink2</href>
    </link>
    <link>
      <label>A label
with
multiple
line 
breaks</label>
      <href>http://myLink3</href>
    </link>
</links>;

trace(doc.descendants("label").text().toXMLString().split("\n"));
/* Trace output (incorrect):
Versions,Configurations,A label
,with
,multiple
,line 
,breaks
*/

var list:Array = [];
doc.descendants("label").(list.push(text().toString()));
trace(list);
/* Trace output (correct):
Versions,Configurations,A label

with

multiple

line 

breaks
*/

That may be useful when performing some complicated searches on an XMLList. However in your case I think you should instead use simple splitting of a string representation or a regular expression as Shane suggests.

edited Jul 26, 2011 at 21:07

answered Jul 26, 2011 at 15:14

Michael Antipin

3,53220 silver badges33 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

user840248 Over a year ago

That's interesting! One silly question more: is there any way to "compact" this 2 lines var list:Array = []; d.descendants("label").(list.push(text().toString())); in a single assignment to the list array? Say, var list = ...

Michael Antipin Over a year ago

Most E4X expressions return an XMLList constructed according to the rules you provide. Search expressions work this way no matter what you do inside the parentheses. What I did in the answer above is I used search expression as a shortcut to looping through XMLList items. But you still can't rely on return value and you need to create an empty array somewhere outside search expression.

shanethehat · Accepted Answer · 2011-07-25 09:08:24Z

0

An alternative technique could be to use a regular expression, although this particular example is dependent on your labels always starting with a capital and otherwise containing only lower case characters.

var regex:RegExp = /[A-Z][a-z]+/g;
var inString:String = "VersionsConfigurations";
var outArray:Array = inString.match(regex);
trace(outArray.length); // 2

answered Jul 25, 2011 at 9:08

shanethehat

15.6k11 gold badges59 silver badges87 bronze badges

3 Comments

user840248 Over a year ago

Shane, I tried methods like this one, but there's a different rule for every node in this XML! The label is only one example, there are lots and every one creates different problems. I tried to propose the XML structure but it seems there's a CMS that creates problems for us the flash developers :-)

shanethehat Over a year ago

Seems your way is safer anyway, until there are newlines in your XML :)

user840248 Over a year ago

It is the toXMLString() that adds lines

Collectives™ on Stack Overflow

E4X/AS3, get an array of text elements without looping

2 Answers 2

2 Comments

3 Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

2 Comments

3 Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related