XSLT for replace attribute in XML element if it exists in another XML?

Question

I have 2 files

catalog.xml

<?xml version="1.0" encoding="UTF-8"?>
<catalog>
    <CD Title="Still got the blues" vinyl="unknown"/>
    <CD Title="When a man loves a woman" vinyl="unknown"/>
</catalog>

vinyl.xml

<?xml version="1.0" encoding="UTF-8"?>
<Vinyl>
    <Album>
        <Title>When a man loves a woman</Title>
        <Vinyl>Yes</Vinyl>
    </Album>
</Vinyl>

How to produce such output.xml with xslt?

<?xml version="1.0" encoding="UTF-8"?>
<catalog>
    <CD Title="Still got the blues" vinyl="unknown"/>
    <CD Title="When a man loves a woman" vinyl="yes"/>***   
</catalog>

***mark this line becouse it changed in output.xml

Emiliano Poggi · Accepted Answer · 2011-08-09 14:09:47Z

4

The following transform, uses catalog.xml as input and loads vinyl.xml using document(). It performs the merge just by making a simple test.

[XSLT 1.0]

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>
    <xsl:variable name="vinyl" select="document('test_i2.xml')"/>

    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="@vinyl">
        <xsl:attribute name="vinyl">
            <xsl:variable name="test" select="
                 $vinyl/Vinyl/Album[Title=current()/../@Title]/Vinyl"/>
            <xsl:choose>
                <xsl:when test="$test">
                    <xsl:value-of select="$test"/>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="."/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:attribute>
    </xsl:template>

</xsl:stylesheet>

This template for the attribute is less immediate, but it exploits pure XPath:

<xsl:template match="@vinyl">
    <xsl:attribute name="vinyl">
        <xsl:value-of select="
          $vinyl/Vinyl/Album[Title=current()/../@Title]/Vinyl
          |
          self::node()[count($vinyl/Vinyl/Album[Title=current()/../@Title])=0]"/>
    </xsl:attribute>
</xsl:template>

edited Aug 9, 2011 at 14:09

answered Aug 9, 2011 at 13:49

Emiliano Poggi

24.9k8 gold badges58 silver badges66 bronze badges

Sign up to request clarification or add additional context in comments.

4 Comments

Emiliano Poggi Over a year ago

Now simplified by matching the attribute directly.

Emiliano Poggi Over a year ago

@Kirill thanks. That's the most immediate answer to me. Would like to see an alternative not using control instructions like choose.

qwazer Over a year ago

@empo really thanks I was making with nested loop on vinyl.xml and catalog.xml. And get upset, becouse no success

Emiliano Poggi Over a year ago

@popalka you are welcome. Thanks for the feedback. See edited answer for full XPath usage.

Collectives™ on Stack Overflow

XSLT for replace attribute in XML element if it exists in another XML?

1 Answer 1

4 Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

4 Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related