Using local variables for a function which "returns" a result

Question

I'm trying to use local variables in a function but it doesn't work as expected.

@echo off
setlocal

call :Sum %1, %2, sum
echo %sum%
exit /b 0

:Sum
setlocal
set "a=%~1"
set "b=%~2"
set /a "%~3=%a%+%b%"
endlocal
exit /b 0

Here is the invocation of the script:

>test.bat 1 2
ECHO is off.

Any clues?

montonero · Accepted Answer · 2022-06-13 12:07:11Z

2

If the expected result is to put sum of arguments into a variable then you'll need to remove setlocal/endlocal inside of :Sum.

:Sum
set "a=%~1"
set "b=%~2"
set /a "%~3=%a%+%b%"
exit /b 0

Or you could try a trick from this answer Batch script make setlocal variable accessed by other batch files

Also using of commas as argument delimiters for call isn't encouraged.

answered Jun 13, 2022 at 12:07

montonero

1,94117 silver badges19 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

montonero Over a year ago

You're welcome. Though I wouldn't rely much on tricks since they aren't documented and not very reliable.

August Karlstrom Over a year ago

I agree in general but in this case it seems to be the only workaround.

urbanSoft · Accepted Answer · 2022-06-13 12:07:38Z

0

You get ECHO is off. because %sum% is not set. Here's an working example:

@echo off
SETLOCAL
CALL :Sum %1, %2, sum
ECHO %sum%
EXIT /B %ERRORLEVEL%

:Sum
SET /A "%~3 = %~1 + %~2"
EXIT /B 0

answered Jun 13, 2022 at 12:07

urbanSoft

7708 silver badges15 bronze badges

1 Comment

August Karlstrom Over a year ago

What I'm looking for is a solution for the general case as described by the title of the question. My example was just an illustration; to add two command-line arguments I don't even need to define a function.

August Karlstrom · Accepted Answer · 2022-06-15 18:01:08Z

0

As mentioned by @montonero, the following hack* solves the problem:

@echo off
setlocal

call :Sum %1 %2 sum
echo %sum%
exit /b 0

:Sum
setlocal
set "a=%~1"
set "b=%~2"
endlocal & (
    set /a "%~3=%a%+%b%"
)
exit /b 0

The command line endlocal & ... works due to the fact that variables are expanded before the command line is executed, thus creating a bridge between the local and the parent scope.

*https://stackoverflow.com/a/18291599/337149

edited Jun 15, 2022 at 18:01

answered Jun 13, 2022 at 12:30

August Karlstrom

11.4k8 gold badges45 silver badges70 bronze badges

Collectives™ on Stack Overflow

Using local variables for a function which "returns" a result

3 Answers 3

2 Comments

1 Comment

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

2 Comments

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related