How to export csv from datagridview only visible column in VB.Net?

Question

I'm working on scraping program, the next step from my program after scraping item is generate/export from datagridview into csv file. I have made the save code like below, but i just want to export only a visible column. How can i do like that?

Private Sub CmdCSV_Click(sender As Object, e As EventArgs) Handles CmdCSV.Click
        Dim sfd As New SaveFileDialog()
        sfd.FileName = "export-csv"
        sfd.Filter = "CSV File | *.csv"

        If sfd.ShowDialog() = DialogResult.OK Then
            Using sw As StreamWriter = File.CreateText(sfd.FileName)
                Dim dgvColumnNames As List(Of String) = DataGridView1.Columns.Cast(Of DataGridViewColumn).ToList().Select(Function(c) c.Name).ToList()

                sw.WriteLine(String.Join(";", dgvColumnNames))

                For Each row As DataGridViewRow In DataGridView1.Rows
                    Dim rowData As New List(Of String)

                    For Each column As DataGridViewColumn In DataGridView1.Columns
                        rowData.Add(Convert.ToString(row.Cells(column.Name).Value))
                    Next
                    sw.WriteLine(String.Join(";", rowData))
                Next

            End Using
        End If
    End Sub

John · Accepted Answer · 2022-06-23 03:54:18Z

1

Firstly, there's no point calling ToList twice here:

Dim dgvColumnNames As List(Of String) = DataGridView1.Columns.Cast(Of DataGridViewColumn).ToList().Select(Function(c) c.Name).ToList()

You don't need a generic List to do the Select, so drop the first ToList:

Dim dgvColumnNames = DataGridView1.Columns.
                                   Cast(Of DataGridViewColumn).
                                   Select(Function(c) c.Name).
                                   ToList()

If you want to filter that list to include only visible columns, that's what you do. The Where method is how you filter:

Dim dgvColumnNames = DataGridView1.Columns.
                                   Cast(Of DataGridViewColumn).
                                   Where(Function(c) c.Visible).
                                   Select(Function(c) c.Name).
                                   ToList()

You should also replace this:

Dim rowData As New List(Of String)

For Each column As DataGridViewColumn In DataGridView1.Columns
    rowData.Add(Convert.ToString(row.Cells(column.Name).Value))
Next

with this:

Dim rowData As New List(Of String)

For Each columnName In dgvColumnNames
    rowData.Add(Convert.ToString(row.Cells(columnName).Value))
Next

or, more simply, this:

Dim rowData = dgvColumnNames.Select(Function(s) row.Cells(columnName).Value.ToString()).ToList()

That last ToList isn't required either, because String.Join accepts an IEnumerable(Of String). Don't take the extra time and effort to convert things to a generic List unless you actually need one.

edited Jun 23, 2022 at 3:54

answered Jun 23, 2022 at 3:47

John

3,2021 gold badge6 silver badges10 bronze badges

Sign up to request clarification or add additional context in comments.

4 Comments

framadh Over a year ago

aah i see, thank you. And i want to ask about header of column. I have header column (i.e Stock Supplier), but why in csv my header is getting from Design Name (STOCK_SUPPLIER) instead of HeaderText (Stock Supplier)? @John

John Over a year ago

@framadh, you need to learn how the DataGridView works. The name of a column and its header text are not the same thing. If you put the names into the file then the file will contain the names, not the header text.

framadh Over a year ago

yeaa, how if I want put the header text into the file instead of names? @John

John Over a year ago

@framadh, that has nothing to do with the topic of the question. You don't ask additional questions in the comments of an answer. If you have another question, post another question. That said, you might want to put some thought and effort into it for yourself first. I find it very hard to believe that you could find out how to get the header text for a grid column if you made the effort to search the web.

Collectives™ on Stack Overflow

How to export csv from datagridview only visible column in VB.Net?

1 Answer 1

4 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

4 Comments

Your Answer

Sign up or log in

Post as a guest

Related