Terraform - Optional Nested Variable

Question

I'm trying to create a module for Sagemaker endpoints. There's an optional object variable called async_inference_config. If you omit it, the endpoint being deployed is synchronous, but if you include it, the endpoint deployed is asynchronous. To satisfy both of these usecases, the async_inference_config needs to be an optional block.

I am unsure of how to make this block optional though.
Any guidance would be greatly appreciated. See example below of structure of the optional parameter.

Example:

resource "aws_sagemaker_endpoint_configuration" "sagemaker_endpoint_configuration" {
  count = var.create ? 1 : 0

  name = var.endpoint_configuration_name
  production_variants {
    instance_type          = var.instance_type
    initial_instance_count = var.instance_count
    model_name             = var.model_name
    variant_name           = var.variant_name
  }
  async_inference_config {
    output_config {
      s3_output_path = var.s3_output_path
    }
    client_config {
      max_concurrent_invocations_per_instance = var.max_concurrent_invocations_per_instance
    }
  }
  lifecycle {
    create_before_destroy = true
    ignore_changes        = ["name"]
  }

  tags = var.tags

  depends_on = [aws_sagemaker_model.sagemaker_model]
}

Update: What I tried based on the below suggestion, which seemed to work

dynamic "async_inference_config" {
    for_each = var.async_inference_config == null ? [] : [true]
    content {
      output_config {
        s3_output_path = lookup(var.async_inference_config, "s3_output_path", null)
      }
      client_config {
        max_concurrent_invocations_per_instance = lookup(var.async_inference_config, "max_concurrent_invocations_per_instance", null)
      }
    }
  }

Marko E · Accepted Answer · 2022-07-27 12:08:19Z

2

You could use a dynamic block [1] in combination with for_each meta-argument [2]. It would look something like:

dynamic "async_inference_config" {
    for_each = var.s3_output_path != null && var.max_concurrent_invocations_per_instance != null ? [1] : []
    content {
    output_config {
      s3_output_path = var.s3_output_path
    }
    client_config {
      max_concurrent_invocations_per_instance = var.max_concurrent_invocations_per_instance
    }
  }
}

Of course, you could come up with a different variable, say enable_async_inference_config (probalby of type bool) and base the for_each on that, e.g.:

dynamic "async_inference_config" {
    for_each = var.enable_async_inference_config ? [1] : []
    content {
    output_config {
      s3_output_path = var.s3_output_path
    }
    client_config {
      max_concurrent_invocations_per_instance = var.max_concurrent_invocations_per_instance
    }
  }
}

[1] https://www.terraform.io/language/expressions/dynamic-blocks

[2] https://www.terraform.io/language/meta-arguments/for_each

edited Jul 27, 2022 at 12:08

answered Jul 21, 2022 at 7:06

Marko E

18.7k4 gold badges29 silver badges37 bronze badges

Sign up to request clarification or add additional context in comments.

13 Comments

Riley Hun Over a year ago

I'm getting an error: │ The argument "async_inference_config.0.output_config.0.s3_output_path" is required, but no definition was found. I set the s3_output_path as null in the variables.tf

Marko E Over a year ago

Which method did you go for, the one with a new variable or the one with multiple variables in for_each?

Riley Hun Over a year ago

I tried both. I adapted your suggestion and used lookups. Added an update in the original post. Not sure if that's best practice though. I'm a terraform novice.

Marko E Over a year ago

If I were to choose, I would go with the second approach. Which combination of parameters caused the error?

Riley Hun Over a year ago

Both approaches complained of the same error. Was saying I needed to make the s3_output_path non null and a string greater than length 1

|

Collectives™ on Stack Overflow

Terraform - Optional Nested Variable

1 Answer 1

13 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

13 Comments

Your Answer

Sign up or log in

Post as a guest

Related