writing/reading a single variable in applescript

Question

I'm just starting with applescript in xcode and currently have an app that asks for a folder location, then creates a folder structure.

on buttonClick_(sender)
    set theLocation to choose folder with prompt "Where to save your project?"
    tell application "Finder"
        set newFolder to make new folder at theLocation with properties {name:(theTextField's stringValue() as string)}
        set fontsFolder to make new folder at newFolder with properties {name:"fonts"}
        set jpgFolder to make new folder at newFolder with properties {name:"jpg-pdf"}
        set mainFolder to make new folder at newFolder with properties {name:"main"}
        set printFolder to make new folder at mainFolder with properties {name:"• for printer"}
        set refverFolder to make new folder at newFolder with properties {name:"ref_ver"}
        set supportFolder to make new folder at newFolder with properties {name:"support"}
    end tell
    quit
end buttonClick_

Now I'm trying to have the app take "theLocation" folder alias and save it, so the next time the app launches it automatically chooses that folder as the save location without having to add it. I understand the logic that will go into it, but I can't figure out how to store/read information. I've tried tutorials on writing to the info.plist, but none of them have worked. Am I missing a basic piece of info on how applescript works?

Thanks

** Edit

script New_ProjectAppDelegate
property parent : class "NSObject"

property theTextField : missing value
property theLocation : ""

on applicationWillFinishLaunching_(aNotification)
    tell standardUserDefaults() of current application's NSUserDefaults
        registerDefaults_({theLocation:theLocation}) -- register the starting user default key:value items
        set theLocation to objectForKey_("theLocation") as text -- read any previously saved items (which will update the values)
    end tell
end applicationWillFinishLaunching_

on buttonClick_(sender)
    if theLocation is "" then
        set theLocation to choose folder with prompt "Where to save your project?"
        tell standardUserDefaults() of current application's NSUserDefaults
            setObject_forKey_(theLocation, "theLocation") -- update the default items
        end tell
    else
        set theLocation to theLocation as text
        --display dialog theLocation as text
    end if
    tell application "Finder"
        set newFolder to make new folder at theLocation with properties {name:(theTextField's stringValue() as string)}
        set fontsFolder to make new folder at newFolder with properties {name:"fonts"}
        set jpgFolder to make new folder at newFolder with properties {name:"jpg-pdf"}
        set mainFolder to make new folder at newFolder with properties {name:"main"}
        set printFolder to make new folder at mainFolder with properties {name:"• for printer"}
        set refverFolder to make new folder at newFolder with properties {name:"ref_ver"}
        set supportFolder to make new folder at newFolder with properties {name:"support"}
    end tell
    quit
end buttonClick_


on applicationShouldTerminate_(sender)
    tell standardUserDefaults() of current application's NSUserDefaults
        setObject_forKey_(theLocation, "theLocation") -- update the default items
    end tell
    return current application's NSTerminateNow
end applicationShouldTerminate_

end script

I am a newbie to apple scripts. Can you tell me how can I edit info.plist.I want to edit some properties in info.plist file with my values.Any help will be appreciated. — user1010819
– user1010819, Commented Oct 14, 2013 at 21:54

score 2 · Accepted Answer · 2011-09-12 21:46:14Z

2

Properties are not persistent in Xcode scripts, but you can utilize the user defaults system. To use the defaults, you register some initial values when your application starts up, then read from the defaults (which will overwrite the registered values if they have been saved before), and when your application quits save the new values - for example:

property theLocation : "" -- this will be the (text) folder path

on applicationWillFinishLaunching_(aNotification)
    tell standardUserDefaults() of current application's NSUserDefaults
        registerDefaults_({theLocation:theLocation}) -- register the starting user default key:value items
        set theLocation to objectForKey_("theLocation") as text -- read any previously saved items (which will update the values)
    end tell
    -- other initialization stuff
end applicationWillFinishLaunching_

on buttonClick_(sender)
    if theLocation is "" then
        set theLocation to choose folder with prompt "Where to save your project?"
        set theLocation to theLocation as text
    end if
    -- display dialog theLocation
    tell application "Finder"
        -- create folder structure
    end tell
    quit
end buttonClick_

on applicationShouldTerminate_(sender)
    tell standardUserDefaults() of current application's NSUserDefaults
        setObject_forKey_(theLocation, "theLocation") -- update the default items
    end tell
    return current application's NSTerminateNow
end applicationShouldTerminate_

edited Sep 12, 2011 at 21:46

answered Sep 12, 2011 at 19:42

user866649

Sign up to request clarification or add additional context in comments.

3 Comments

Steve Kelly Over a year ago

This is exactly the direction I'm looking for, but the application is still not recognizing theLocation as having a default value when I open it. In order to use the NSUserDefaults do I have to initialize it anywhere or import a class? I'll add my entire code to the original post.

user866649 Over a year ago

NSUserDefaults only supports objects that can be represented in a property list, so for an alias you will need to create an NSData object to hold it, or (easier in this case, I think) coerce the folder path to text. I've updated the buttonClick_ handler in my example to show the path coercion (you will also see plist errors like this in the debug console).

Steve Kelly Over a year ago

I see it now! I was only setting the alias to text if the location already existed in the defaults, which wasn't doing anything, rather than setting it to text after the 'choose folder' was issued. It is working now, and I thank you for the help.

fireshadow52 · Accepted Answer · 2011-09-12 18:47:47Z

0

You can define a property at the beginning of your script, which allows you to store information even after the script quits...

property theLocation : null
if theLocation is null then set theLocation to (choose folder with prompt "Where to save your project?"
...

The script will store the alias in "theLocation" for future use. However, saving or recompiling the script will reset the property back to its original value.

answered Sep 12, 2011 at 18:47

fireshadow52

6,5662 gold badges34 silver badges48 bronze badges

Collectives™ on Stack Overflow

writing/reading a single variable in applescript

2 Answers 2

3 Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

3 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related