Easiest way to open a text file and read it into an array with Perl

Question

Adding a standard Perl file open function to each script I have is a bit annoying:

sub openfile{
    (my $filename) = @_;
    open FILE,"$filename" or die $!;
    my @lines = <FILE>;
    return @lines;
}

and I can create a Perl module to do this, but this is so simple I'm sure there should be one out there already.

I'm trying to find a way to read a text file into an array, and I cant seem to find a Perl module out there that can do this simple task... maybe I'm looking too hard and it already came with the standard 5.10 install.

Optimally I believe it would look something like this:

my @lines = Module::File::Read("c:\some\folder\structure\file.txt");

I would highly recommend Text::CSV::Slurp for anyone wanting to work with CSV files. This module worked much better than the two or three others I tried. The next best was CSV::Slurp::Simple or something along those lines, though not as robust as Text::CSV::Slurp. — Brian
– Brian, Commented Apr 28, 2009 at 19:11

innaM · Accepted Answer · 2009-04-18 19:58:58Z

28

You have several options, the classic do method:

my @array = do {
    open my $fh, "<", $filename
        or die "could not open $filename: $!";
    <$fh>;
};

The IO::All method:

use IO::All;

my @array = io($filename)->slurp;

The File::Slurp method:

use File::Slurp;

my @array = read_file($filename);

And probably many more, after all TIMTOWTDI.

edited Apr 18, 2009 at 19:58

innaM

48k5 gold badges72 silver badges88 bronze badges

answered Apr 17, 2009 at 20:41

Chas. Owens

65.1k25 gold badges139 silver badges232 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

Brian Over a year ago

Definately like the File::Slurp method. Thank you so much!

Martin von Wittich Over a year ago

Note that File::Slurp predates the Perl IO layers, and therefore won't honor the PERL_UNICODE/perl -C settings which may be surprising when you're trying to write Perl scripts with proper Unicode support. Path::Tiny might be an alternative with better Unicode support.

dfa · Accepted Answer · 2009-04-17 17:32:37Z

16

that is the famous "slurp mode":

  my @lines = <FILEHANDLE> ;

you may also see Perl Slurp Ease

answered Apr 17, 2009 at 17:32

dfa

117k32 gold badges193 silver badges229 bronze badges

2 Comments

ysth Over a year ago

"slurp mode" is more commonly used to mean reading the whole file into a single scalar, by setting the record separator $/ to undef.

codehearted Over a year ago

I've seen both array and scalar context described as slurp mode, but I've seen the array style used more often.

neomorphic · Accepted Answer · 2009-04-17 17:32:49Z

15

I think this is what you are looking for

File::Slurp

answered Apr 17, 2009 at 17:32

neomorphic

5885 silver badges15 bronze badges

Comments

AndyG · Accepted Answer · 2017-04-21 15:25:31Z

7

Also have a look at Perl6::Slurp which implements the Perl6 version of slurp and is recommended in the "Perl Best Practices" book.

Some examples....

my @lines         = slurp 'filename';
my @lines_chomped = slurp 'filename', { chomp => 1 };
my @lines_utf8    = slurp 'filename', { utf8  => 1 };

edited Apr 21, 2017 at 15:25

AndyG

41.5k8 gold badges123 silver badges155 bronze badges

answered Apr 17, 2009 at 20:28

draegtun

22.6k5 gold badges51 silver badges72 bronze badges

Comments

Joe Suarez · Accepted Answer · 2009-08-20 19:59:15Z

6

You might also want to consider using Tie::File, particularly if you are reading larger files and don't want to read the entire file into memory. It's a core module. Also, please refer to perlfaq5.

edited Aug 20, 2009 at 19:59

answered Apr 17, 2009 at 18:15

Joe Suarez

5631 gold badge8 silver badges22 bronze badges

Comments

chaos · Accepted Answer · 2009-04-17 17:36:14Z

4

You've gotten the general techniques, but I want to put in that Perl sort of discourages you from doing that because it's very often the case that you can do the same thing you're doing one-line-at-a-time, which is inherently far more efficient.

answered Apr 17, 2009 at 17:36

chaos

125k34 gold badges306 silver badges310 bronze badges

1 Comment

Chas. Owens Over a year ago

A good point, especially when reading into an array. Arrays imply sequential processing by lines (or records if $/ is being used) which is often better done one-item-at-a-time. However, there are cases where it is appropriate to slurp.

Axeman · Accepted Answer · 2009-04-21 21:55:23Z

2

For quick and dirty, I rather like the simplicity of mucking with @ARGV.

# Ysth is right, it doesn't automatically die; I need another line.
use 5.010;
use strict;
my @rows = do { 
    use warnings FATAL => 'inplace'; # oddly enough, this is the one. ??
    @ARGV='/a/file/somewhere';
    <>;
};
say q(Not gettin' here.);

~~If perl* cannot open the file, it automatically dies.~~

* - the executable, so please don't capitalize.

edited Apr 21, 2009 at 21:55

answered Apr 17, 2009 at 18:56

Axeman

29.9k2 gold badges50 silver badges104 bronze badges

4 Comments

Brian Over a year ago

I didn't know that Perl wasn't an abbreviation! Thanks for the heads up.

Axeman Over a year ago

Sorry, the note was not for you but for the notorious Capital-P gang. They'll break into your post and capitalize your P's when you specifically meant the executable. The language gets a capital-P--only. There's no anagram, though.

ysth Over a year ago

I thought the capital-P gang was careful to distinguish.

ysth Over a year ago

No, perl does not automatically die - it just warns and continues.

Starfish · Accepted Answer · 2013-11-20 05:37:34Z

2

I would recommend an object oriented approach that does not requires modules outside the CORE distribution and will work anywhere:

use strict;
use warnings;
use IO::File;
my $fh = IO::File->new("< $file");

foreach ($fh->getlines) {
    do_something($_);
}
$fh->close

edited Nov 20, 2013 at 5:37

Starfish

1,09010 silver badges23 bronze badges

answered Apr 19, 2009 at 16:30

Беров

1,39112 silver badges22 bronze badges

Collectives™ on Stack Overflow

Easiest way to open a text file and read it into an array with Perl

8 Answers 8

2 Comments

2 Comments

Comments

Comments

Comments

1 Comment

4 Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

8 Answers 8

2 Comments

2 Comments

Comments

Comments

Comments

1 Comment

4 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related