Convert a binary string of 0s and 1s to a bitstring in elixir

Question

Given a string such as "0110", how do I convert this to a bitstring containing the binary values represented by the string?

I checked the Base module, but it's based on RFC 4648 and is not designed for handling Base 2.

Adam Millerchip · Accepted Answer · 2023-07-07 02:30:00Z

3

Here's one way:

defmodule Convert do
  def to_bitstring(str) when is_binary(str) do
    for <<byte::binary-1 <- str>>, into: <<>> do
      case byte do
        "0" -> <<0::1>>
        "1" -> <<1::1>>
      end
    end
  end
end

Usage:

iex> Convert.to_bitstring("0110")
<<6::size(4)>>

The benefit of doing it exhaustively using case and matching on binaries is two-fold:

The function will reject invalid characters
The error message in the above case is easy to understand:

iex> Convert.to_bitstring("0140")
** (CaseClauseError) no case clause matching: "4"

If you just want a quick hack, this works, but it will also happily convert nonsense like "0140" too, so I think the first solution is better.

for <<byte <- str>>, into: <<>>, do: <<(byte - ?0)::1>>

answered Jul 7, 2023 at 2:30

Adam Millerchip

23.3k6 gold badges62 silver badges86 bronze badges

Sign up to request clarification or add additional context in comments.

4 Comments

Aleksei Matiushkin Over a year ago

for <<byte <- str>>, (byte in [?0, ?1] || raise "boom"), …

sabiwara Over a year ago

Or keep the case but match on ?0 and ?1

Adam Millerchip Over a year ago

@sabiwara sure but then you lose the point 2) above and get errors like ** (CaseClauseError) no case clause matching: 52

sabiwara Over a year ago

Oh you're right. I missed that, nice!

Collectives™ on Stack Overflow

Convert a binary string of 0s and 1s to a bitstring in elixir

1 Answer 1

4 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

4 Comments

Your Answer

Sign up or log in

Post as a guest

Related