How to read value of a node in Perl libXML::Reader

Question

My XML looks like this-

<info>
<name>NameGoesHere</name>
<age>99</age>
</info>

Using XML::LibXML::Reader, I would like to print the age.

I read the documentation from here, and I am looking for an example. I am able to use $reader->nextElement('info') and then print innerXML but not able to figure out how do I print only age and not the whole innerxml.

Community · Accepted Answer · 2017-05-23 12:13:51Z

3

Try localName:

#!/usr/bin/perl
use strict;
use warnings;
use XML::LibXML::Reader;

my $reader = XML::LibXML::Reader->new(IO => \*DATA)
    or die "Cannot read from \\*DATA\n";

while ( $reader->read ) {
    print $reader->readInnerXml if $reader->localName eq 'age';
}

$reader->finish;

__DATA__
<info>
<name>NameGoesHere</name>
<age>99</age>
</info>

Mostly from Regex: keep everything in <profession></profession> tags

edited May 23, 2017 at 12:13

CommunityBot

11 silver badge

answered Oct 11, 2011 at 18:35

Philip Durbin

4,0922 gold badges29 silver badges37 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

user837208 Over a year ago

Thanks! It would be great if someone can suggest any other alternative too. I don't like "filtering" using if statement - it will be more elegant if I can directly access the value

ikegami · Accepted Answer · 2011-10-11 19:29:31Z

use strict;
use warnings;
use feature qw( say );

use XML::LibXML::Reader qw(
   XML_READER_TYPE_ELEMENT
   XML_READER_TYPE_END_ELEMENT
   XML_READER_TYPE_TEXT
);

my $reader = XML::LibXML::Reader->new(IO => \*DATA);

my $in_age = 0;
my $age;
while ($reader->read()) {
   if ($reader->nodeType() == XML_READER_TYPE_ELEMENT && $reader->name() eq 'age') {
      $age = '' if !$in_age;
      ++$in_age;
   }
   elsif ($reader->nodeType() == XML_READER_TYPE_END_ELEMENT && $reader->name() eq 'age') {
      --$in_age;
      say $age if !$in_age;
   }
   elsif ($in_age && $reader->nodeType() == XML_READER_TYPE_TEXT) {
      $age .= $reader->value();
   }
}

__DATA__
<info>
<name>NameGoesHere</name>
<age>99</age>
</info>

Collectives™ on Stack Overflow

How to read value of a node in Perl libXML::Reader

2 Answers 2

1 Comment

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related