1

So I am trying to set multiple variables with a For Loop in a Batch file. I know I need to use EnableDelayedExpansion but I have tested out several different methods and so far nothing seems to work. Also, this will generally be run as a domain user that does not have a user folder on the computer.

The end goal is to collect the file path for notes.ini for each user directory. Originally I would repeat a section for each folder and change the variable to n1 then n2 then n3. I am trying to compact this and allow this file to handle any number of user folders. I need to be able to call each path individually latter int the batch file, so currently I have each path written to a txt file then the txt file parsed into a variable.

This is my original code:

SETLOCAL EnableDelayedExpansion
for /D %%x in ("C:\Users\*") do (
if exist %temp%\niresults.txt del /q %temp%\niresults.txt
dir "%%x\AppData\Local\lotus\Notes\*.*" /L /A /B /S|Find "notes.ini" >> %temp%\niresults.txt
If not exist %temp%\niresults.txt echo "Files not found"
set /p n1= < %temp%\niresults.txt
if exist C:\niresults.txt del /q C:\niresults.txt
)

I plan on using the variables in the following way.

wscript "FnR.vbs" "Find this" "Replace with this" !n1!

or 

wscript "FnR.vbs" "Find this" "Replace with this" %n1% %n2% %n3%... etc

FnR.vbs is setup to accept and process parameters 3 through x in a loop so the number of parameters doesn't matter too much; however, FnR does take a little while to run. I thought about including the wscript "FnR.vbs" in the loop but currently I have to call it 4 times for each file location and will do that if I have to but it will slow everything way down.

So is there a way to get this to work so that each path will be in a different variable or change the name of the txt file for each time the loop is run? or omit the txt file and dump the output directly into a variable (I think this might be what I need most to get it to work with EnableDelayedExpansion)?

The easiest solution would be, is it possible to change n1 to n2 at the second iteration of the loop and n3 at the 3rd and so on.

I know I could back out and search a larger directory of C:\users for the files but with the amount of user data on most of the machines in my environment that would make the file take longer to run that the actions it would replace.

Improve this question
5
  • Your question is unclear. ‘is there a way to get this to work as is?’ – you are not telling us how it is, actually. One could try to get the meaning of the script from the code itself, but that would still not answer the question whether the script does what it is intended to do. So far it seems like it is supposed to collect the paths to the notes.ini files located in certain folders. But it is unclear why the n1 variable is assigned the output file's first line at every iteration of the loop. Commented Oct 22, 2011 at 17:16
  • ‘I plan on using the variables…’ – what variables exactly? You mentioned n1, n2 etc. elsewhere, but there's only n1 at the moment. Commented Oct 22, 2011 at 17:16
  • I edited the question and I believe I clarified the information you mentioned. Commented Oct 25, 2011 at 13:56
  • Please have a look at the approach used in Aacini's answer to this question. Commented Oct 26, 2011 at 18:23
  • I'm fairly certain that does it. post that link as an answer and I will accept it. Commented Oct 27, 2011 at 4:23

2 Answers 2

Reset to default
1

Alternatively to using 'indexed' variables, you could use a 'list' variable for collecting all the names in the loop and then just reference it later in the command line that calls the VB script. Something like this:

SETLOCAL EnableDelayedExpansion
set nlist=0
for /D %%x in ("C:\Users\*") do (
if exist %temp%\niresults.txt del /q %temp%\niresults.txt
dir "%%x\AppData\Local\lotus\Notes\*.*" /L /A /B /S|Find "notes.ini" >> %temp%\niresults.txt
If not exist %temp%\niresults.txt echo "Files not found"
set /p n1= < %temp%\niresults.txt
set nlist=!nlist! "!n1!"
if exist C:\niresults.txt del /q C:\niresults.txt
)
:: now all the names are in the %nlist% variable,
:: so you can call the VB script like this
wscript "FnR.vbs" "Find this" "Replace with this" %nlist%
Improve this answer
Sign up to request clarification or add additional context in comments.

3 Comments

This is perfect. I had written my piece like your other answer but this one will make it easiest so I am accepting this one. Thanks for your time and effort.
I had to wrap n1 in ! but it works. Thank you. set nlist=!nlist! "!n1!"
Oh, that was a silly mistake! Of course, I meant !n1! too, thanks for letting me know about it!
1

You could take the approach used by Aacini in their answer to this question.

Here's how your script might look like with that approach:

SETLOCAL EnableDelayedExpansion
set i=0
for /D %%x in ("C:\Users\*") do (
if exist %temp%\niresults.txt del /q %temp%\niresults.txt
dir "%%x\AppData\Local\lotus\Notes\*.*" /L /A /B /S|Find "notes.ini" >> %temp%\niresults.txt
If not exist %temp%\niresults.txt echo "Files not found"
set /a i+=1
set /p n!i!= < %temp%\niresults.txt
if exist C:\niresults.txt del /q C:\niresults.txt
)
:: now that you've got an 'array' of n1, n2, n3 etc.
:: you can reference any or all of them as appropriate
wscript "FnR.vbs" "Find this" "Replace with this" "%n1%" "%n2%" "%n3%" ...
Improve this answer

Comments

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Start asking to get answers

Find the answer to your question by asking.

Ask question

Explore related questions

See similar questions with these tags.