How calculate business days between dates

I believe you just need this:

=NETWORKDAYS.INTL(dt_initial, dt_final,1)-NETWORKDAYS.INTL(dt_initial,dt_initial,1)

NETWORKDAYS.INTL(dt_initial, dt_final,1) calculates business days between initial date and final date, both inclusive.

NETWORKDAYS.INTL(dt_initial,dt_initial,1) checks whether initial_date is a business day or not, if it is, deduct one from NETWORKDAYS.INTL(dt_initial, dt_final,1), if not leave NETWORKDAYS.INTL(dt_initial, dt_final,1) ast it is.

You can use my DateDiffWorkdays function:

Date1 = #2024-08-19#
Date2 = #2024-08-20#
? DateDiffWorkdays(Date1, Date2)
 1 

Date1 = #2024-08-19#
Date2 = #2024-08-21#
? DateDiffWorkdays(Date1, Date2)
 2 

Date1 = #2024-08-15#
Date2 = #2024-08-20#
? DateDiffWorkdays(Date1, Date2)
 3 

The function:

' Returns the count of full workdays between Date1 and Date2.
' The date difference can be positive, zero, or negative.
' Optionally, if WorkOnHolidays is True, holidays are regarded as workdays.
'
' Note that if one date is in a weekend and the other is not, the reverse
' count will differ by one, because the first date never is included in the count:
'
'   Mo  Tu  We  Th  Fr  Sa  Su      Su  Sa  Fr  Th  We  Tu  Mo
'    0   1   2   3   4   4   4       0   0  -1  -2  -3  -4  -5
'
'   Su  Mo  Tu  We  Th  Fr  Sa      Sa  Fr  Th  We  Tu  Mo  Su
'    0   1   2   3   4   5   5       0  -1  -2  -3  -4  -5  -5
'
'   Sa  Su  Mo  Tu  We  Th  Fr      Fr  Th  We  Tu  Mo  Su  Sa
'    0   0   1   2   3   4   5       0  -1  -2  -3  -4  -4  -4
'
'   Fr  Sa  Su  Mo  Tu  We  Th      Th  We  Tu  Mo  Su  Sa  Fr
'    0   0   0   1   2   3   4       0  -1  -2  -3  -3  -3  -4
'
' Execution time for finding working days of three years is about 4 ms.
'
' Requires table Holiday with list of holidays.
'
' 2015-12-19. Gustav Brock. Cactus Data ApS, CPH.
'
Public Function DateDiffWorkdays( _
    ByVal Date1 As Date, _
    ByVal Date2 As Date, _
    Optional ByVal WorkOnHolidays As Boolean) _
    As Long
    
    Dim Holidays()      As Date
    
    Dim Diff            As Long
    Dim Sign            As Long
    Dim NextHoliday     As Long
    Dim LastHoliday     As Long
    
    Sign = Sgn(DateDiff("d", Date1, Date2))
    If Sign <> 0 Then
        If WorkOnHolidays = True Then
            ' Holidays are workdays.
        Else
            ' Retrieve array with holidays between Date1 and Date2.
            Holidays = DatesHoliday(Date1, Date2, False) 'CBool(Sign < 0))
            ' Ignore error when using LBound and UBound on an unassigned array.
            On Error Resume Next
            NextHoliday = LBound(Holidays)
            LastHoliday = UBound(Holidays)
            ' If Err.Number > 0 there are no holidays between Date1 and Date2.
            If Err.Number > 0 Then
                WorkOnHolidays = True
            End If
            On Error GoTo 0
        End If
        
        ' Loop to sum up workdays.
        Do Until DateDiff("d", Date1, Date2) = 0
            Select Case Weekday(Date1)
                Case vbSaturday, vbSunday
                    ' Skip weekend.
                Case Else
                    If WorkOnHolidays = False Then
                        ' Check for holidays to skip.
                        If NextHoliday <= LastHoliday Then
                            ' First, check if NextHoliday hasn't been advanced.
                            If NextHoliday < LastHoliday Then
                                If Sgn(DateDiff("d", Date1, Holidays(NextHoliday))) = -Sign Then
                                    ' Weekend hasn't advanced NextHoliday.
                                    NextHoliday = NextHoliday + 1
                                End If
                            End If
                            ' Then, check if Date1 has reached a holiday.
                            If DateDiff("d", Date1, Holidays(NextHoliday)) = 0 Then
                                ' This Date1 hits a holiday.
                                ' Subtract one day to neutralize the one
                                ' being added at the end of the loop.
                                Diff = Diff - Sign
                                ' Adjust to the next holiday to check.
                                NextHoliday = NextHoliday + 1
                            End If
                        End If
                    End If
                    Diff = Diff + Sign
            End Select
            ' Advance Date1.
            Date1 = DateAdd("d", Sign, Date1)
        Loop
    End If
    
    DateDiffWorkdays = Diff

End Function

It requires some supporting functions - too much code to post here - which all can be found in the modules at my repository at GitHub: VBA.Date.

Note, that it also allows for excluding holidays held in a holiday table.

I've added for you an Excel demo in the demos folder: DateWork.xlsm.

Not sure if this fits your use case, but this is what works for me. I use NETWORKDAYS to exclude weekends, and then subtract 1 from the result. If you want to exclude holidays, you'll need to put a third parameter after the end date.

=NETWORKDAYS(start_date, end_date)-1

Using this method, if your start and end dates are the same, you will get 0 days as the result. I interpret that as no days have elapsed between start and end, which is valid for my need.