Two nested while loops on same array become infinite (they shouldn't)

Question

I have a minimal working example of two nested while loops on the same array @g:

#!/usr/bin/env perl

use 5.042;
no source::encoding;
use warnings FATAL => 'all';
use feature 'say';
use autodie ':default';

my @g = qw(Matthew Mark Luke John);
while (my ($i, $gos) = each @g) {
    say "$i => $gos";
    while (my ($j, $g2) = each @g) {
        say "\t$j=>$g2";
    }
}

This particular loop gets stuck on the first iteration $i, and never moves on to the 2nd.

The infinity is easily fixed by foreach my $gos (@gos) { instead of the first while.

Is this a bug or an intended feature?

Shouldn't foreach my $gos (@g) in the first line be the exact equivalent of while (my ($i, $gos) = each @g) {?

Not just an infinite loop. The inner loop skips index 0

ikegami
– ikegami

2025-10-15 13:58:01 +00:00
Commented Oct 15 at 13:58 — ikegami
– ikegami, Commented Oct 15 at 13:58
You should state what output you thought you would get.

TLP
– TLP

2025-10-15 15:12:21 +00:00
Commented Oct 15 at 15:12 — TLP
– TLP, Commented Oct 15 at 15:12

ikegami · Accepted Answer · 2025-10-15 13:55:47Z

5

The problem is that both invocations of each use the same list iterator. From the perldoc:

Each hash or array has its own internal iterator, accessed by each, keys, and values. The iterator is implicitly reset when each has reached the end [...]

After returning all elements, the iterator returns an empty list in the inner loop, upon which it restarts from the beginning. This is why your outer loop never progresses beyond the first element: all remaining elements are consumed by the inner loop on every iteration.

The repeated output you're seeing clearly demonstrates the shared iterator behavior:

0=>Matthew     # Consumed by outer loop
    1=>Mark    # Consumed by inner loop
    2=>Luke    # Consumed by inner loop
    3=>John    # Consumed by inner loop
    ()         # Iterator is exhausted and reset. Loop exits
0=>Matthew     # A fresh iterator
    1=>Mark
    2=>Luke
    3=>John
    ()         # Iterator is exhausted and reset. Loop exits
# ... and so on

You should use foreach instead.

edited Oct 15 at 13:55

ikegami

391k17 gold badges291 silver badges555 bronze badges

answered Oct 15 at 1:07

Robby Cornelissen

98.6k23 gold badges154 silver badges180 bronze badges

Sign up to request clarification or add additional context in comments.

3 Comments

ikegami Oct 15 at 13:47

Just wanna add a bit to what you said: "while-each" loop are risky because exiting one using last, return or an exception can leave the array or hash's iterator in an unexpected place. Using a sufficiently new Perl, you can use for my ($idx, $val) (builtin::indexed @array) as an efficient and safer alternative

con Oct 15 at 16:30

indexed is the best solution, IMHO

ikegami Oct 15 at 16:46

Especially since you're already enforcing 5.42

brian d foy · Accepted Answer · 2025-10-16 16:20:47Z

4

Since you are using v5.42, you should use foreach and indexed which is designed to do just this:

use 5.042;
$|=1;

my @g = qw(Matthew Mark Luke John);

foreach my($i, $gos) ( indexed @g ) {
    say "$i => $gos";

    foreach my($j, $g2) ( indexed @g ) {
        say "\t$j=>$g2";
        }
    }

edited Oct 16 at 16:20

answered Oct 15 at 14:47

brian d foy

134k31 gold badges214 silver badges613 bronze badges

Collectives™ on Stack Overflow

Two nested while loops on same array become infinite (they shouldn't)

2 Answers 2

3 Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

3 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related