extract part of file name using batch file

Question

I have loop, where I'll copy all *.txt files to big.txt in the same directory. In each loop step I want additional copys of different files in different folders with the same first three characters in file name from files in first directory.

Example:

\A\001.txt
\A\003.txt
\A\005.txt
\A\big.txt
\B\001_sth.xml
\B\002_sth.xml - don't copy! no 002 in folder A
\B\003_sth.xml
\B\004_sth.xml - don't copy! no 004 in folder A
\B\005_sth.xml
\B\big.xml

In step 1: copy \A\001.txt to \A\big.txt AND \B\001_sth.xml to \B\big.xml etc

I wrote the batch file to only copy files in directory A, but I have no idea how to find files directory B.

@echo off
if "%1"=="" goto error 
for %%x in (%1\A\*.txt) do (
    copy %%x %1\A\big.txt
    echo %%x
    echo ---
)   

goto end    
:error
echo give me a directory    
:end

lavinio · Accepted Answer · 2011-12-06 23:13:19Z

3

Why not just enumerate files in A and then reference files in B?

for %%I in (%1\A\*.txt) do (
    copy %1\B\%%~nI_sth.xml %1\B\big.xml
    echo %%I
    echo ---
)   
goto :EOF

(by the way it's not wise to use lower case x for your loop variable because %%~sdfnx all have special meaning)

edited Dec 6, 2011 at 23:13

lavinio

24.4k5 gold badges57 silver badges72 bronze badges

answered Dec 6, 2011 at 16:44

John Knoeller

34.3k4 gold badges66 silver badges93 bronze badges

Sign up to request clarification or add additional context in comments.

3 Comments

Andriy M Over a year ago

What is %%x? Did you mean %%I?

Andriy M Over a year ago

Ah, I see now, it's there because you used the OP's example as a starting point. Sorry about asking silly questions.

Borgo Over a year ago

This is what I needed: ~n. Thanks! Also thanks for a good tip about %%x.

dbenham · Accepted Answer · 2011-12-06 22:02:14Z

2

I don't understand the purpose of your code. Each time you copy to big.txt you over-write the previous copy. I think you want to append instead.

I'm not sure if you want to start with an empty big.txt and big.xml. I'm assuming you do.

Also, your question implies the source text files could have more than 3 characters in the name, even though your example has exactly 3. I'm assuming you want to support more than 3.

If I understand you correctly, I think this will work (untested) Edit - made changes in response to Andriy M comments regarding initial setlocal and avoiding self-copy of big.txt

@echo off
setlocal disableDelayedExpansion
if "%~1"=="" echo Give me a directory&exit /b
set "root=%~1"
if exist "%root%\A\big.txt" del "%root%\A\big.txt"
if exist "%root%\B\big.xml" del "%root%\B\big.xml"
for /f "delims=" %%F in ('dir /b "%root%\A\*.txt"') do (
  type "%root%\A\%%~F" >>"%root%\A\big.txt"
  set "prefix=%%~nF"
  setlocal enableDelayedExpansion
  type "!root!\B\!prefix:~0,3!*.xml" >>"!root!\B\big.xml"
  endlocal
)

The toggling of the delayed expansion within the loop is only needed if ! appears in any of the paths. Since this is unlikely, you can probably start out with delayed expansion enabled and drop the toggling.

edited Dec 6, 2011 at 22:02

answered Dec 6, 2011 at 20:26

dbenham

132k29 gold badges273 silver badges410 bronze badges

7 Comments

Andriy M Over a year ago

Might be worthwhile to watch for big.txt as the value of %%F to prevent an attempt of self-copying.

Andriy M Over a year ago

And I've got a question: does setlocal (without arguments) imply setlocal DisableDelayedExpansion?

dbenham Over a year ago

SETLOCAL without arg will equate to SETLOCAL DisableDelayedExpansion for most environments, but it would be better to be explicit. I edited the answer. The solution will never attempt to self-copy big.txt because it is deleted prior to starting the loop. The IN() clause is fully evaluated prior to executing the DO block.

Andriy M Over a year ago

Re "IN() clause is fully evaluated prior to executing…": I would think as much, and in fact I did think so until I saw this question.

Andriy M Over a year ago

And thanks for the clarification on SETLOCAL, didn't know that (must have missed the relevant bit in the docs).

|

Tim · Accepted Answer · 2011-12-06 13:39:09Z

1

These would help;

http://www.microsoft.com/resources/documentation/windows/xp/all/proddocs/en-us/batch.mspx?mfr=true

http://ss64.com/nt/

answered Dec 6, 2011 at 13:39

Tim

6998 silver badges27 bronze badges

Collectives™ on Stack Overflow

extract part of file name using batch file

3 Answers 3

3 Comments

7 Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

3 Comments

7 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related