STDOUT to array Perl

Question

I am compiling a Perl program, i am writing the output STDOUT to a file. In the same program , i want to run another small script using while function on the output of STDOUT. So, I need to save the output of first script in an array, then i can use in while<@array>. Like

open(File,"text.txt");
open(STDOUT,">output,txt");
@file_contents=<FILE>;

foreach (@file_contents){

//SCRIPT GOES HERE//

write;
}
format STDOUT =
VARIABLE    @<<<<<< @<<<<<<  @<<<<<<
             $x      $y       $z
.

//Here I want to use output of above program in while loop //

while(<>){

}

How can i save the output of first program into array so that i can use in while loop, or how can i directly use STDOUT in while loop. I have to make sure that first part is completely executed. Thanks in advance.

I think you are walking down a bad path here. Using perlform might not be the best option, if you need to further process the data within the same program. — TLP
– TLP, Commented Jan 11, 2012 at 15:42

Jonathan Leffler · Accepted Answer · 2012-01-11 07:11:32Z

Since you remapped STDOUT so it writes to a file, you could presumably close STDOUT, and then reopen the file for reading.

Quite where you're going to send any other output is a bit of a mystery, but presumably you can resolve that. Were it me, I'd not fiddle with STDOUT. I'd make the script write to a file handle:

use strict;
use warnings;

open my $input, "<", "text.txt" or die "A horrible death";
open my $output, ">", "output.txt" or die "A horrible death";
my @file_contents = <$input>;
close($input);

foreach (@file_contents)
{
    # Script goes here
    print $output "Any information that goes to output\n";
}
close $output;

open my $reread, "<", "output.txt" or die "A horrible death";

while (<$reread>)
{
    # Process the previous output
}

Note the use of lexical file handles, the checking that the open worked, the close when finished with the input file, the use of use strict; and use warnings;. (I've only been working with Perl for 20 years and I know I don't trust my scripts until they run clean with those settings.)

Community · Accepted Answer · 2017-05-23 12:12:10Z

I assume you want to reopen STDOUT in order to make the write function work. However, the correct solution for that is to either specify the file handle, or to a lesser extent, to use select.

write FILEHANDLE;

or

select FILEHANDLE;
write;

Unfortunately, it seems the IO of perlform is a bit arcane, and does not seem to allow for lexical file handles.

Your problem is you can't reuse the formatted text within the program, so a bit of trixy programming is required. What you can do is open a file handle that prints to a scalar. Which is another somewhat arcane perl functionality, but in this case, it might be the only way to do this directly.

# Using FOO as format to avoid destroying STDOUT
format FOO =
VARIABLE    @<<<<<< @<<<<<<  @<<<<<<
             $x      $y       $z
.

my $foo;
use autodie;  # save yourself some typing
open INPUT, '<', "text.txt"; # normally, we would add "or die $!" on these
open FOO, '>', \$foo;        # but now autodie handles that for us
open my $output, '>', "output.txt";

while (<FILE>) {
    $foo = "";            # we need to reset $foo each iteration
    write FOO;            # write to the file handle instead
    print $output $foo;   # this now prints $foo to output.txt
    do_something($foo);   # now you can also process the text at the same time
}

As you'll notice, we now first print the formatted line to the scalar $foo. While it is there, we can handle it as regular data, so there's no need to save to a file and reopening it to get to the data.

Each iteration, data is concatenated to the end of $foo, so to avoid accumulation, we need to reset $foo. The best way to handle this would be to make $foo lexical within the scope, but unfortunately we need $foo to be declared outside the while loop in order to be able to use it in the open statement.

It might be possible to use local $foo inside the while-loop, but I think that's adding yet more bad practice to this already very bad hack.

Conclusion:

With all this said and done, I suspect the best way to handle this is to not use perlform at all, and format your data in some other way. While perlform might be well suited to print to a file, it is not the best suited for what you have in mind. I recall this question from earlier, perhaps there was some other answer that would work better. Such as using sprintf, like Jonathan suggested

Alex Reynolds · Accepted Answer · 2012-01-11 10:00:04Z

0

Assuming the output from your first program is tab-delimited:

while (<>) {
    chomp $_;
    my ($variable, $x, $y, $z) = split("\t", $_);
    # do stuff with values
}

edited Jan 11, 2012 at 10:00

answered Jan 11, 2012 at 7:09

Alex Reynolds

97.3k59 gold badges251 silver badges356 bronze badges

Collectives™ on Stack Overflow

STDOUT to array Perl

3 Answers 3

Comments

Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related