Dynamic function generation with macros

Question

I am putting together a macro to generate simple functions of the style:

(defun hello ()
  (format t "hello~&"))

Each new function will have hello replaced.

(defmacro generate-echoers (list)
  `(let ((list-of-functions
         (loop for var in ,list
            collect
              `(defun ,(intern var) ()
                 (format t ,(concatenate var "~&"))))))
  `(progn
     ,list-of-functions)))

I developed the above function, which demonstrates conclusively that I have not yet masted quote-times and phases of expansion.

The desired usage is as follows: (generate-echoers '("hi" "ping" "pong")) => ;A list of functions that each say their name, as HELLO does above.

Rainer Joswig · Accepted Answer · 2012-01-19 22:42:17Z

7

A function to generate:

(defun hello ()
  (format t "hello~&"))

I would first write a function which creates above code:

(defun make-echoers (name)
  `(defun ,(intern (string-upcase name)) ()
     (format t ,(concatenate 'string name "~&"))))

Note that symbols are by default uppercase in Common Lisp - so we are using uppercase, too.

Then you can test it:

CL-USER 1 > (make-echoers "hello")
(DEFUN HELLO NIL (FORMAT T "hello~&"))

Works. Now let's use it:

(defmacro generate-echoers (list)
  `(progn ,@(mapcar #'make-echoers list)))

Test it:

CL-USER 2 > (macroexpand-1 '(generate-echoers ("hi" "ping" "pong")))
(PROGN
  (DEFUN HI NIL (FORMAT T "hi~&"))
  (DEFUN PING NIL (FORMAT T "ping~&"))
  (DEFUN PONG NIL (FORMAT T "pong~&")))

answered Jan 19, 2012 at 22:42

Rainer Joswig

140k11 gold badges230 silver badges357 bronze badges

Sign up to request clarification or add additional context in comments.

3 Comments

Paul Nathan Over a year ago

Interesting, I didn't think of making a defun to generate the defun. Problem's already solved, but +1!

James Porter Over a year ago

apologies for thread necro; is it possible to alter this so that one can pass a symbol whose value is the list ("hi" "ping" "pong"), rather than pass the list directly? I tried using ,list, but this failed.

Rainer Joswig Over a year ago

@James Porter: you would need to make sure that the symbol value is retrieved. For example by changing the macro to check for a symbol and trying to retrieve a symbol value. Opens another can of worms...

Vsevolod Dyomkin · Accepted Answer · 2012-01-18 23:27:37Z

4

Your code can be simplified and made more correct like this:

(defmacro generate-echoers (list)
  `(progn ,@(loop :for var :in list
               :collect `(defun ,(intern (format nil "~:@(~A~)" var)) ()
                           (format t ,(concatenate 'string var "~&"))))))

First of all, you've got to splice the loop's result into the generated body.

Also you've forgotten, that concatenate takes type parameter and to upcase all your vars (otherwise you'll get function names like |foo|).

answered Jan 18, 2012 at 23:27

Vsevolod Dyomkin

9,4912 gold badges35 silver badges37 bronze badges

1 Comment

Paul Nathan Over a year ago

The `(progn ,@(loop solved it for me. The rest I sorted out on my own. Thanks a lot!

Clayton Stanley · Accepted Answer · 2012-01-19 17:21:29Z

1

If you pass symbols to the generate-echoers macro (instead of strings), the intern call is no longer necessary:

(defmacro generate-echoers (&rest echoers)
  `(progn
     ,@(mapcar (lambda (var)
                 `(defun ,var () 
                    (format t ,(format nil "~(~a~)~&" var))))
               echoers)))

edited Jan 19, 2012 at 17:21

answered Jan 19, 2012 at 15:44

Clayton Stanley

7,8349 gold badges36 silver badges50 bronze badges

2 Comments

Paul Nathan Over a year ago

The name of the function needs to be SYMBOL or a list according to the Hyperspec. I don't grasp the list part, I think it has to be setf'able. I was passing in a list of strings. I bet you were passing in a list of symbols?

Paul Nathan Over a year ago

Also, I like the mapcar. Much cleaner than loop here.

Collectives™ on Stack Overflow

Dynamic function generation with macros

3 Answers 3

3 Comments

1 Comment

2 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

3 Comments

1 Comment

2 Comments

Your Answer

Sign up or log in

Post as a guest

Related