Querying XML with LINQ by attribute

Question

Given the following XML file:

<users>
  <user name="admin" password="foobar" roles="Admin,Guest" />
  <user name="guest" password="foobar" roles="Guest" />
</users>

How do I find a specific node? In this case I want to find the node that has its name attribute to be "admin"

    Dim authGroup As XElement = XElement.Parse(myXMLDoc.OuterXml)
    Dim foundUser As IEnumerable(Of XElement) = From i In authGroup.Elements Where i.Attributes("name") = "admin" Select i

    'How can I determine if the user was found?
    Dim p As String =  ...... (get the password from foundUser)

Jeff Mercado · Accepted Answer · 2012-03-02 14:43:23Z

2

Dim doc As XElement =
    <users>
        <user name="admin" password="foobar" roles="Admin,Guest" />
        <user name="guest" password="foobar" roles="Guest" />
    </users>
Dim userName = "admin"

Dim result =
    doc.Descendants("user")                                                    _
       .Where(Function(user) CType(user.Attribute("name"), String) = userName) _
       .SingleOrDefault

If result IsNot Nothing Then
    ' user found '
    Dim pw = CType(result.Attribute("password"), String)
    ' do something with pw '
End If

edited Mar 2, 2012 at 14:43

answered Mar 2, 2012 at 14:35

Jeff Mercado

136k34 gold badges268 silver badges282 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

WhiskerBiscuit Over a year ago

What type is "doc"? The Descendants function is not being found.

Jeff Mercado Over a year ago

It should come back as an XElement as that is an XML literal (without the declaration)

Meysam · Accepted Answer · 2012-03-02 14:36:07Z

2

Dim root As XElement = XElement.Load("users.xml")
Dim admin As XElement = root.Elements().FirstOrDefault(Function(u) u.Attribute("name").Value = "admin")
If admin IsNot Nothing Then
    Dim password As String = admin.Attribute("password").Value
End If

edited Mar 2, 2012 at 14:36

answered Mar 2, 2012 at 14:24

Meysam

18.3k47 gold badges145 silver badges232 bronze badges

Collectives™ on Stack Overflow

Querying XML with LINQ by attribute

2 Answers 2

2 Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

2 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related