options for using "identify" command with public api

I ended up just doing the string manipulation. I'll vote to close this as "too broad" but I wanted to post my full code here in case it helps anyone.

Excel VBA using VBA-WEB library:

Option Explicit

Sub updateData()
    Dim i As Integer
    On Error Resume Next

    Dim tbl As ListObject
    Dim tRows As Long
    Dim tCols As Long

    Set tbl = ActiveSheet.ListObjects("Participants")

    For i = 1 To tbl.ListRows.Count
        getAddressData (i)
    Next i


End Sub


Sub getDistrict(rw As Integer, spatialReference As Object, location As Object, extent As Object)
    Dim wkid As String
    wkid = spatialReference("wkid")
    Dim latestWkid As String
    latestWkid = spatialReference("latestWkid")

    Dim x As String
    x = location("x")
    Dim y As String
    y = location("y")

    Dim xmin As String
    xmin = extent("xmin")
    Dim ymin As String
    ymin = extent("ymin")
    Dim xmax As String
    xmax = extent("xmax")
    Dim ymax As String
    ymax = extent("ymax")

    Dim geometry As String
    geometry = "{""x"":" & x & "," & """y"":" & y & ",""spatialReference"":{""wkid"":" & wkid & ",""latestWkid"":" & latestWkid & "}}"

    Dim mapExtent As String
    mapExtent = "{""xmin"":" & xmin & ",""ymin"":" & ymin & ",""xmax"":" & xmax & ",""ymax"":" & ymax & ",""spatialReference"":{""wkid"":" & wkid & ",""latestWkid"":" & latestWkid & "}}"


    Dim arcClient As New WebClient
    arcClient.BaseUrl = "https://ogi.oa.mo.gov/ArcGIS/rest/services/LEGIS/legisDistrict/MapServer/"

    ' Note: querystring params are automatically url-encoded
    Dim Request As New WebRequest
    Request.Resource = "identify"
    Request.AddQuerystringParam "f", "json"
    Request.AddQuerystringParam "geometry", geometry
    Request.AddQuerystringParam "tolerance", "1"
    Request.AddQuerystringParam "returnGeometry", "false"
    Request.AddQuerystringParam "mapExtent", mapExtent
    Request.AddQuerystringParam "imageDisplay", "1599,845,96"
    Request.AddQuerystringParam "geometryType", "esriGeometryPoint"
    Request.AddQuerystringParam "sr", wkid
    Request.AddQuerystringParam "layers", "visible:1"

    ' By default: Request.Method = WebMethod.HttpGet and Request.Format = WebFormat.Json

    Dim Response As WebResponse
    Set Response = arcClient.Execute(Request)

    If Response.StatusCode = WebStatusCode.Ok Then
        Dim district As String
        Dim name As String
        district = Response.Data("results")(1)("attributes")("District")
        name = Response.Data("results")(1)("attributes")("Name")
        Cells(rw, "R").Value = district
        Cells(rw, "S").Value = name
    Else
        MsgBox "Error: " & Response.Content
    End If
End Sub

Sub getAddressData(rw As Integer)
    Dim address As String
    address = Cells(rw, "Q").Value
    Dim arcClient As New WebClient
    arcClient.BaseUrl = "https://geocode.arcgis.com/arcgis/rest/services/World/GeocodeServer/"

    ' Note: querystring params are automatically url-encoded
    Dim Request As New WebRequest
    Request.Resource = "findAddressCandidates"
    Request.AddQuerystringParam "SingleLine", address
    Request.AddQuerystringParam "f", "json"
    Request.AddQuerystringParam "outSR", "{""wkid"":102100,""latestWkid"":3857}"
    Request.AddQuerystringParam "outFields", "*"

    ' By default: Request.Method = WebMethod.HttpGet and Request.Format = WebFormat.Json

    Dim Response As WebResponse
    Set Response = arcClient.Execute(Request)

    If Response.StatusCode = WebStatusCode.Ok Then
        Dim spatialReference As Dictionary
        Dim location As Dictionary
        Dim extent As Dictionary
        Set spatialReference = Response.Data("spatialReference")
        Set location = Response.Data("candidates")(1)("location")
        Set extent = Response.Data("candidates")(1)("extent")
        getDistrict rw, spatialReference, location, extent
    Else
        MsgBox "Error: " & Response.Content
    End If

End Sub