Split hash by array value

Question

If there's a hash where one of the values is an array, what's the shortest way to split into an array-of-hashes (AoH) for each array value that keeps all the hash keys and values, except for replacing the original array with individual values?

The following illustrates the functional goal, but I feel like there's some map or similar magic that could do this as a one-liner.

use strict;
use warnings;
use Data::Dumper;

my @result;

my %hash = (
    a => "string",
    b => [ "13", "14", "15" ],
    c => "another string",
);

foreach my $b (@{$hash{'b'}}) {
    push @result, { %hash };
    $result[-1]{'b'} = $b;
}

print Dumper(\@result);

Desired outcome:

$VAR1 = [
          {
            'b' => '13',
            'a' => 'string',
            'c' => 'another string'
          },
          {
            'c' => 'another string',
            'a' => 'string',
            'b' => '14'
          },
          {
            'b' => '15',
            'c' => 'another string',
            'a' => 'string'
          }
        ];

Rawley Fowler · Accepted Answer · 2025-10-09 18:14:43Z

5

You are correct, you can use map to do this by mapping over the b values, also instead of editing the thing you just pushed, construct the new hashes with the modified b values:

use strict;
use warnings;
use Data::Dumper;

my %hash = (
    a => "string",
    b => [ "13", "14", "15" ],
    c => "another string",
);

my @result = map {
  +{
    %hash,
    b => $_
  }
} @{$hash{b}};

print Dumper(\@result);

answered Oct 9 at 18:14

Rawley Fowler

3,13712 silver badges21 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

Kaz Utashiro · Accepted Answer · 2025-11-09 05:53:35Z

0

It's not that short, but a generic solution.

use strict;
use warnings;
use Data::Dumper;

my %hash = (
    a => "string",
    b => [ "13", "14", "15" ],
    c => "another string",
);

use List::Util 1.39 qw(pairs reduce);

my @result = map @$_, reduce { [
    map {
        my @a = %$_;
        map {
            +{ @a, $b->key => $_ }
        } ref $b->value ? @{$b->value} : $b->value;
    } @$a
] } [ +{} ], pairs %hash;

print Dumper \@result;

answered Nov 9 at 5:53

Kaz Utashiro

214 bronze badges

Collectives™ on Stack Overflow

Split hash by array value

2 Answers 2

2 Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

2 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related