I need to achieve the following in perl
printmsg(@val1, $msg1) if @val1;
printmsg(@val2, $msg2) if @val2;
printmsg(@val3, $msg3) if @val3;
printmsg(@val4, $msg4) if @val4;
printmsg(@val5, $msg5) if @val5;
printmsg(@val6, $msg6) if @val6;
So i wrote the following snippet
for(my $i=1; $i < 6; $i++ ) {
printmsg(@val$i, $msg$i) if @val$i;
}
It doesn't work and breaks out with errors.
Whenever you find yourself postfixing variable names with an integer index, realize that you should have used an array instead:
my @msgs = ('msg1', 'msg2', ..., 'msg6');
my @vals = ( [ @val1 ], [ @val2 ], ..., [ @val6 ] );
See also the FAQ How can I use a variable as a variable name?
As the answer to the FAQ notes, if the variables are not indexed by an integer, you can use a hash table:
By using symbolic references, you are just using the package's symbol-table hash (like
%main::) instead of a user-defined hash. The solution is to use your own hash or a real reference instead.$USER_VARS{"fred"} = 23; my $varname = "fred"; $USER_VARS{$varname}++; # not $$varname++
You should read the entire FAQ list at least once a year.
Update: I purposefully left symbolic references out of my answer because they are unnecessary and likely very harmful in the context of your question. For more information, see Why it's stupid to 'use a variable as a variable name'?, part 2 and part 3 by mjd.
You can't just string variables together like that and get a resulting variable. You COULD evaluate the expression of $msg + i, but it's probably better if you make msg an array and just index: $msg[$i].
If I understand, you need "eval"!
for(my $i=1; $i < 6; $i++ ) {
eval 'printmsg(@val'. $i . ', $msg' . $i .') if @val' . $i;
}
But remember! All variable(@val1, @val2, ..., @valN) must exists! As you're not providing too much of your code I'm unavaiable to infer more about this problem. Maybe you could provide more code huh?
Trying to interpolate that with an eval is an interesting solution, and it looks like it would work. I never considered trying to assemble the variable names using an eval. But the reason is an array just works better, and is probably the technically correct solution.
Instead of trying to concatenate "$var" and "$i" to form "$var1" inside an eval, just use an array and access $var[$i]. The code would look like this.
#!/usr/bin/perl -w
my @arrayOfReferences;
push @arrayOfReferences, [qw(this is array 1)];
push @arrayOfReferences, [qw(this is array 2)];
push @arrayOfReferences, [qw(this is array 3)];
push @arrayOfReferences, [qw(this is array 4)];
push @arrayOfReferences, [qw(this is array 5)];
push @arrayOfReferences, [qw(this is array 6)];
my @arrayOfMessages = qw(Message1 Message2 Message3 Message4 Message5 Message6);
for (my $i=0; $i < @arrayOfMessages; $i++){
&printmsg($arrayOfReferences[$i],$arrayOfMessages[$i]);
}
sub printmsg{
($arrayRef, $message) = @_;
print "Array Value: " . join(" ",@$arrayRef) . "\n"; #dereference pointer here
print "Message String: $message\n\n";
}
Output looks like this
perl evalVariableInterpolation.pl
Array Value: this is array 1
Message String: Message1
Array Value: this is array 2
Message String: Message2
Array Value: this is array 3
Message String: Message3
Array Value: this is array 4
Message String: Message4
Array Value: this is array 5
Message String: Message5
Array Value: this is array 6
Message String: Message6
