Parsing Tab Delimited File into an array

Question

I am attempting to read a CSV into an array in a way that I can access each column in a row. However when I run the following code with the goal of printing a specific column from each row, it only outputs empty lines.

#set command line arguments
my ($infi, $outdir, $idcol) = @ARGV;

#lead file of data to get annotations for
open FILE, "<", $infi or die "Can't read file '$infi' [$!]\n";
my @data;
foreach my $row (<FILE>){
    chomp $row;
    my @cells = split /\t/, $row;
    push @data, @cells;
}


#fetch genes
foreach (@data){
    print "@_[$idcol]\n";
#    print $geneadaptor->fetch_by_dbID($_[$idcol]);
}

With a test input of

a       b       c
1       2       3
d       e       f
4       5       6

I think the issue here isn't so much loading the file, but in treating the resulting array. How should I be approaching this problem?

Are you sure you shouldn't be using a hash instead of an array? — Francisco R
– Francisco R, Commented Apr 4, 2013 at 16:48
Would a hash be equivalent to a python dictionary? If so, then yeah it'd make more sense to use that. — Joe
– Joe, Commented Apr 5, 2013 at 12:53

Borodin · Accepted Answer · 2013-04-04 16:45:11Z

4

First of all you need to push @data, \@cells, otherwise you will get all the fields concatenated into a single list.

Then you need to use the loop value in the second for loop.

foreach (@data){
    print $_->[$idcol], "\n";
}

@_ is a completely different variable from $_ and is unpopulated here.

You should also consider using

while (my $row = <FILE>) { ... }

to read your file. It reads only a single line at a time whereas for will read the entire file into a list of lines before iterating over it.

answered Apr 4, 2013 at 16:45

Borodin

127k9 gold badges72 silver badges146 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Francisco R · Accepted Answer · 2013-04-04 17:19:50Z

1

I recommend to avoid parsing the CSV file directly and using the Text::CSV module.

use Text::CSV;
use Carp;

#set command line arguments
my ($infi, $outdir, $idcol) = @ARGV;

my $csv = Text::CSV->new({
  sep_char => "\t"
});

open(my $fh, "<:encoding(UTF-8)", $infi) || croak "can't open $infi: $!";

# Uncomment if you need to skip header line
# <$fh>;

while (<$fh>) {
    if ($csv->parse($_)) {
        my @columns = $csv->fields();
        print "$columns[0]\t$columns[1]\t$columns[2]\n";
    } else {
        my $err = $csv->error_input;
        print "Failed to parse line: $err";
    }
}
close $fh;

edited Apr 4, 2013 at 17:19

answered Apr 4, 2013 at 17:11

Francisco R

4,0471 gold badge24 silver badges37 bronze badges

4 Comments

Borodin Over a year ago

The text/tab-separated-values MIME type is defined very simply so that data cannot contain the tab character. There is no quote or escape character, so the correct way to parse tab-separated data is with a simple split /\t/. To set up Text::CSV correctly you also have to suppress quote_char and escape_char and it should end up just splitting on tabs, and the module loses all of its value.

Francisco R Over a year ago

thanks for the tip, but the questioner said "I am attempting to read a CSV", so I can't assume the file doesn't include quotes or escape character...

Borodin Over a year ago

That was clearly a misconception as a CSV is, by definition, comma-separated.

Joe Over a year ago

Sorry about that mix up. I am parsing gene annotation which has quote characters due to the annotations being packed with every character and delimiter under the sun. I mixed up CSV and TSV because the files I have come to me in either form. I was unaware that TSV didn't allow for such characters as I've always found them, but then again biologists make these files...

Collectives™ on Stack Overflow

Parsing Tab Delimited File into an array

2 Answers 2

Comments

4 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

4 Comments

Your Answer

Sign up or log in

Post as a guest

Related