Nested environment variables

Question

I am trying to make a file that asks for your username and password, with a registration. When registering, the passwords are saved in variables.

The problem is i have to set names for those variables, names that would be input when you write your username down. for example, i need a password for the user "john". When the username john is written down by a user, it is stocked in a variable, %user1%. As i need to make a variable %johnpass% and "john"= %user1%, i have to therefore make a variable called %%user1%pass% (Variable INSIDE a variable.CRAZY!)

Is there another way to do this???

SIMPLE VERSION:

User writes username "john"
"john" is saved in a variable, %user1%
he writes a password "1q2p"
how can i save this password in a variable: which would be: %user1%'s password
%%user1%pass% is not working

I really want to find out! If you have a script for registration and login, please tell!!! Thanks in advance.

Nate Hekman · Accepted Answer · 2013-05-03 17:46:23Z

4

You can use "delayed expansion" to solve the problem of the nested variables. For example, !%user1%pass!: the ! is like % but signals that expansion should be delayed, so %user1% will be expanded first, leaving you with !johnpass! which can be expanded next.

Here's a complete script:

@echo off
setlocal enabledelayedexpansion

set /p "user1=Username: "
set /p "%user1%pass=Password: "

echo %user1%'s password is !%user1%pass!

answered May 3, 2013 at 17:46

Nate Hekman

6,6771 gold badge29 silver badges30 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

Swillfreat Over a year ago

Thanks! Had heard of delayed expansion, but never realized how useful it could be!

Nate Hekman Over a year ago

You're welcome. If this answered your question, please mark it as Accepted. I see you've asked a few other questions for which you've left comments on an answer saying it was helpful--please consider marking those as Accepted as well. That helps other people with the same question later to quickly find an answer, as well as rewarding those who took the time to respond.

Community · Accepted Answer · 2017-05-23 11:43:19Z

You method have an important drawback: How do you know how many different variables are you managing? How do you know that the next user will use user2 variable and the next one user3? You must agree that if there is just one user then password variable don't require the user name and could be named just pass, right?

The standard method to deal with this situation is via an array: you use a variable with same name (the array) and select different values from it via a subscript. In your case, you may have two arrays: user and pass, both with the same numeric subscript starting from 1. For example:

@echo off
setlocal EnableDelayedExpansion
set index=0

:nextUser
set /A index+=1
set /P "user[%index%]=Username: "
set /P "pass[%index%]=Password: "

rem Display data of user[1]:
echo %user[1]%'s password is %pass[1]%

rem Display data of all users, from 1 to %index%
for /L %%i in (1,1,%index%) do (
   echo !user[%%i]!'s password is !pass[%%i]!
)

You may read a detailed description about array management in Batch files at this post: Arrays, linked lists and other data structures in cmd.exe (batch) script

Collectives™ on Stack Overflow

Nested environment variables

2 Answers 2

2 Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

2 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related