Store arithmetic operators in an array with Fortran

Question

I would like to solve a given equation of the following kind with Fortran:

1 ? 2 ? 3 = 7

In this equation only the arithmetic operators are missing and the solution would be '+' for the first question mark and '*' for the second one. I would like to write a short script that finds the correct operators by brute force. So in this case four times four cases would have to be checked. In order to do this I would like to store the operators in an array and use them in a nested do loop:

    value1=1
    value2=2
    value3=3
    result=7

    op(1)=+
    op(2)=-
    op(3)=/
    op(4)=*

    do i=1,4
       do j=1,4
          if(value1 op(i) value2 op(j) value3 .eq. result) then
             write(*,*)'Found solution: ' ,op(i), op(j)
          else
             j=j+1
          endif
       enddo
    i=i+1
    enddo

Apparently this doesn't work because of the wrong interpretation of the if-statement. Any ideas how to make this work?

Community · Accepted Answer · 2017-05-23 12:05:22Z

4

As Vladimir pointed out, you can't do it directly that way in Fortran, unless you use function pointers. Below you find an according example.

I made it simple by using integer operations only. Also note, that I assumed that the operations in your expression are executed from left to right (no precedence rules), otherwise the algorithm would be much more complicated. If precedence matters, you should think about using an interpreted language for the task (unless execution speed is cruical).

Here is the module defining the operations and a type containing procedure pointers:

module myfuncs
  implicit none

  abstract interface
    function binary(i1, i2)
      integer, intent(in) :: i1, i2
      integer :: binary
    end function binary
  end interface

  type :: procptr
    procedure(binary), pointer, nopass :: ptr
  end type procptr

contains

  function add(i1, i2) result(res)
    integer, intent(in) :: i1, i2
    integer :: res
    res = i1 + i2
  end function add

  function mul(i1, i2) result(res)
    integer, intent(in) :: i1, i2
    integer :: res
    res = i1 * i2
  end function mul

  function sub(i1, i2) result(res)
    integer, intent(in) :: i1, i2
    integer :: res
    res = i1 - i2
  end function sub

  function div(i1, i2) result(res)
    integer, intent(in) :: i1, i2
    integer :: res
    res = i1 / i2
  end function div

end module myfuncs

Here is the main program with the brute force search:

program bruteforce
  use myfuncs

  type(procptr) :: ops(4)
  character :: opnames(4)
  integer :: val1, val2, val3, res, myres

  val1 = 1
  val2 = 2
  val3 = 3
  res = 7

  ops(1)%ptr => add
  ops(2)%ptr => sub
  ops(3)%ptr => mul
  ops(4)%ptr => div
  opnames = [ "+", "-", "*", "/" ]

  lpi: do ii = 1, 4
    lpj: do jj = 1, 4
      myres = ops(jj)%ptr(ops(ii)%ptr(val1, val2), val3)
      write(*,"(3(I0,1X,A,1X),I0)") val1, opnames(ii), val2, &
          &opnames(jj), val3, " = ", myres
      if (myres == res) then
        write(*,*) "Solution found."
        exit lpi
      end if
    end do lpj
  end do lpi

end program bruteforce

edited May 23, 2017 at 12:05

CommunityBot

11 silver badge

answered May 16, 2013 at 18:16

Bálint Aradi

3,81220 silver badges22 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

user2390654 Over a year ago

Thank you very much for your work! Though, I am afraid that I will have to consider precendece rules. Also, I actually wanted to solve more than just two operation equations (up to 7). So, maybe I should switch to another language, as you suggested. Do you have any particular suggestions for a language that would be suited for this kind of problem and is easy to handle?

Bálint Aradi Over a year ago

All of those are fine, which offer an eval()-like construct, being able to evaluate a string containing a valid expression in that language. If you already know such a language, take that. Otherwise Python or Ruby could be possible choices, where in my (definitely biased) oppinion former is somewhat closer in its philosophy to Fortran, so it may be easiser for you to learn. But just have a look at them and decide yourself.

Vladimir F Героям слава · Accepted Answer · 2013-05-16 16:09:33Z

1

This cannot be done in Fortran. What type did you declare for op? There isn't any that would fit. One thing you could do is to define some functions and store function pointers to them.

answered May 16, 2013 at 16:09

Vladimir F Героям слава

60.7k4 gold badges82 silver badges131 bronze badges

Collectives™ on Stack Overflow

Store arithmetic operators in an array with Fortran

2 Answers 2

2 Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

2 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related