For loop only loops once

Question

I have a very weird error occurring in my Batch script where a For loop is only looping once when it should loop many more times (at least 10 times).

Can you tell me why my For loop is only looping once and how I can fix it?

@ECHO off
CLS
SETLOCAL 

SET macroFolder=_PLACE_4DM_FILES_HERE

REM the following for loop only loops once when it should be looping more 
REM because theres over 10 *.4dm files in the folder??
for /r ./%macroFolder% %%i in ("*.4dm") do SET "file=%%i" (
    echo %file%
    REM Note I need to store %%i in a variable so I can edit it later
    REM And placing %%i in a variable within the for loop results in 
    REM the var being empty for some reason. For eg
    SET file=%%i
    ECHO file is %file%
    REM Prints "file is "
)

ECHO.
PAUSE
ENDLOCAL

try this: for /r "./%macroFolder%" %%i in ("*.4dm") do echo(%%i — Endoro
– Endoro, Commented May 23, 2013 at 4:42
You must note that ./%macroFolder% form is exactly the same than just %macroFolder%, that is, %macroFolder% folder in current directory, and usually never used! — Aacini
– Aacini, Commented May 23, 2013 at 5:26

paxdiablo · Accepted Answer · 2013-05-23 04:50:58Z

5

You have (at least) two problems. The first is that you seem to be mixing the bracketed and non-bracketed form of the for statement:

for /r ./%macroFolder% %%i in ("*.4dm") do SET "file=%%i" (
    blah blah
)

In that case, the non-bracketed bit is executed per-loop-iteration but the bracketed bit executes after loop exit. You can see this with:

for /r ./%macroFolder% %%i in ("*.4dm") do echo 1 (
    echo 2
)

which outputs (in my case where there are three 4dm files):

1 (
1 (
1 (
2

Your second problem is that %% variable expansion is done before the command executed and the for command is a multi-line one, from the for to the closing ) bracket. Any variables you need expanded, that have been set within the loop, need to be done with delayed expansion.

Start with this:

@SETLOCAL enableextensions enabledelayedexpansion
@ECHO off
CLS

SET macroFolder=4dmfiles

for /r ./%macroFolder% %%i in ("*.4dm") do (
    SET file=%%i
    ECHO file is !file!
)

ECHO.
PAUSE
ENDLOCAL

and you'll see (for my three files):

file is C:\Users\Pax\Documents\4dmfiles\1.4dm
file is C:\Users\Pax\Documents\4dmfiles\2.4dm
file is C:\Users\Pax\Documents\4dmfiles\3.4dm

edited May 23, 2013 at 4:50

answered May 23, 2013 at 4:44

paxdiablo

889k243 gold badges1.6k silver badges2k bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Aacini Over a year ago

+1 Good explanation! I had never seen the form for /r ./%macroFolder% %%i in ("*.4dm") do SET "file=%%i" ( blah blah ) before!

Collectives™ on Stack Overflow

For loop only loops once

1 Answer 1

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related