How can I dynamically include Perl modules without using eval?

Question

I need to dynamically include a Perl module, but if possible would like to stay away from eval due to work coding standards. This works:

$module = "My::module";
eval("use $module;");

But I need a way to do it without eval if possible. All google searches lead to the eval method, but none in any other way.

Is it possible to do it without eval?

I'd get your coding standards updated. There's nothing wrong or insecure about eval'ing what is basically a hard coded string. It's the simplest way to accomplish what you want. If you're passing in user input, that's another story... — runrig
– runrig, Commented Dec 16, 2009 at 22:45

Michael Carman · Accepted Answer · 2009-12-16 20:58:26Z

51

Use require to load modules at runtime. It often a good idea to wrap this in a block (not string) eval in case the module can't be loaded.

eval {
    require My::Module;
    My::Module->import();
    1;
} or do {
   my $error = $@;
   # Module load failed. You could recover, try loading
   # an alternate module, die with $error...
   # whatever's appropriate
};

The reason for the eval {...} or do {...} syntax and making a copy of $@ is because $@ is a global variable that can be set by many different things. You want to grab the value as atomically as possible to avoid a race condition where something else has set it to a different value.

If you don't know the name of the module until runtime you'll have to do the translation between module name (My::Module) and file name (My/Module.pm) manually:

my $module = 'My::Module';

eval {
    (my $file = $module) =~ s|::|/|g;
    require $file . '.pm';
    $module->import();
    1;
} or do {
    my $error = $@;
    # ...
};

edited Dec 16, 2009 at 20:58

answered Dec 16, 2009 at 20:01

Michael Carman

30.9k10 gold badges80 silver badges124 bronze badges

Sign up to request clarification or add additional context in comments.

12 Comments

innaM Over a year ago

Hmm. This is good because you wrap the require in an eval, but your require isn't particularly dynamic. If one could merge answers, Dan's and your's would be my top candidates.

user226723 Over a year ago

While his require wasn't dynamic, I was easily able to make it so (as Picard would say). Thanks for the answer!

tsee Over a year ago

@Ether: You're right to say it's not safe, (before the edit) but it's not related to threads.

ephemient Over a year ago

s@'|::@/@g -- for hysterical raisins, ' and :: are interchangeable as package delimiters.

Michael Carman Over a year ago

Anyone who uses ' as a package delimiter outside of a JAPH deserves to have their code break.

|

DavidGamba · Accepted Answer · 2012-11-01 14:46:52Z

17

How about using the core module Module::Load

With your example:

use Module::Load;
my $module = "My::module";
load $module;

"Module::Load - runtime require of both modules and files"

"load eliminates the need to know whether you are trying to require either a file or a module."

If it fails it will die with something of the like "Can't locate xxx in @INC (@INC contains: ...".

edited Nov 1, 2012 at 14:46

answered Nov 1, 2012 at 14:37

DavidGamba

3,6432 gold badges34 silver badges47 bronze badges

2 Comments

alexk Over a year ago

It's a core module, so should be used.

Chris Dodd Over a year ago

Do you have an example of how to make this work with a dynamic string? When I try it, I just get Useless use of hash element in void context and/or Can't call method "autoload" on unblessed reference

Dan · Accepted Answer · 2009-12-16 20:15:35Z

10

Well, there's always require as in

require 'My/Module.pm';
My::Module->import();

Note that you lose whatever effects you may have gotten from the import being called at compile time instead of runtime.

Edit: The tradeoffs between this and the eval way are: eval lets you use the normal module syntax and gives you a more explicit error if the module name is invalid (as opposed to merely not found). OTOH, the eval way is (potentially) more subject to arbitrary code injection.

edited Dec 16, 2009 at 20:15

answered Dec 16, 2009 at 20:04

Dan

11.1k7 gold badges55 silver badges82 bronze badges

1 Comment

user226723 Over a year ago

Thanks for the answer. I voted you up since I can't select both answers :).

Ether · Accepted Answer · 2009-12-16 21:20:10Z

4

No, it's not possible to without eval, as require() needs the bareword module name, as described at perldoc -f require. However, it's not an evil use of eval, as it doesn't allow injection of arbitrary code (assuming you have control over the contents of the file you are requireing, of course).

EDIT: Code amended below, but I'm leaving the first version up for completeness.

~~I use~~ I used to use this little sugar module to do dynamic loads at runtime:

package MyApp::Util::RequireClass;

use strict;
use warnings;

use Exporter 'import'; # gives you Exporter's import() method directly
our @EXPORT_OK = qw(requireClass);

# Usage: requireClass(moduleName);
# does not do imports (wrong scope) -- you should do this after calling me: $class->import(@imports);
sub requireClass
{
    my ($class) = @_;
    eval "require $class" or do { die "Ack, can't load $class: $@" };
}

1;

PS. I'm staring at this definition (I wrote it quite a while ago) and I'm pondering adding this: $class->export_to_level(1, undef, @imports);... it should work, but is not tested.

EDIT: version 2 now, much nicer without an eval (thanks ysth): :)

package MyApp::Util::RequireClass;

use strict;
use warnings;

use Exporter 'import'; # gives you Exporter's import() method directly
our @EXPORT_OK = qw(requireClass);

# Usage: requireClass(moduleName);
# does not do imports (wrong scope) -- you should do this after calling me: $class->import(@imports);
sub requireClass
{
    my ($class) = @_;

    (my $file = $class) =~ s|::|/|g;
    $file .= '.pm';
    require $file;  # will die if there was an error
}

1;

edited Dec 16, 2009 at 21:20

answered Dec 16, 2009 at 20:16

Ether

54.2k13 gold badges91 silver badges162 bronze badges

2 Comments

ysth Over a year ago

"require() needs the bareword module name" - no, it doesn't; just s#::#/#g; and append '.pm' to get a pathname.

Ether Over a year ago

@ysth: wow, you're right... the docs are very vague about this but it does indeed work. Well that's splendid, now I can revise my module to eliminate that evil eval :)

szabgab · Accepted Answer · 2014-04-05 20:55:13Z

1

Class::MOP on CPAN has a load_class method for this: http://metacpan.org/pod/Class::MOP

edited Apr 5, 2014 at 20:55

szabgab

6,31211 gold badges56 silver badges64 bronze badges

answered Jun 23, 2011 at 17:24

Terrence Brannon

5,0228 gold badges47 silver badges68 bronze badges

Comments

ShoeLace · Accepted Answer · 2012-11-06 23:31:59Z

0

i like doing things like..

require Win32::Console::ANSI if ( $^O eq "MSWin32" );

answered Nov 6, 2012 at 23:31

ShoeLace

3,6063 gold badges33 silver badges44 bronze badges

Collectives™ on Stack Overflow

How can I dynamically include Perl modules without using eval?

6 Answers 6

12 Comments

2 Comments

1 Comment

2 Comments

Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

6 Answers 6

12 Comments

2 Comments

1 Comment

2 Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related