Windows batch For Loop dropping empty strings to the end

Question

I have this following code.

@echo off
setlocal EnableDelayedExpansion
set holdingline=,Measure,,+ X,,,0,0
FOR /F "tokens=1,2,3,4,5,6,7,8 delims=," %%a IN ("%holdingline%") DO (
    echo %%a
    echo %%b
    echo %%c
    echo %%d
    echo %%e
    echo %%f
    echo %%g
    echo %%h
    echo %holdingline%
)
pause

Output displayed is as below:

Measure
+ X
0
0
ECHO is off.
ECHO is off.
ECHO is off.
ECHO is off.
,Measure,,+ X,,,0,0

The empty strings are pushed to the end and I wonder why. I am expecting them in order, say something like:

ECHO is off.
Measure
ECHO is off.
+ X
ECHO is off.
ECHO is off.
0
0
,Measure,,+ X,,,0,0

This would enable me to assign them to the correct variables. I tried searching but did not find much help.

Magoo · Accepted Answer · 2015-04-15 06:04:05Z

2

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
set holdingline=,Measure,,+ X,,,0,0
FOR /F "tokens=1-8 delims=," %%a IN (""%holdingline:,=","%"") DO (
    ECHO(%%~a
    ECHO(%%~b
    ECHO(%%~c
    ECHO(%%~d
    ECHO(%%~e
    ECHO(%%~f
    ECHO(%%~g
    ECHO(%%~h
    echo %holdingline%
)

GOTO :EOF

This should solve your problem

To process a file, producing a new file

@ECHO OFF
SETLOCAL
(
FOR /f "delims=" %%x IN (q29639243.txt) DO (
 set "holdingline=%%x"
 CALL :process
)
)>u:\new.txt

GOTO :EOF

:process
FOR /F "tokens=1-8 delims=," %%a IN (""%holdingline:,=","%"") DO (
    ECHO(%%~a
    ECHO(%%~b
    ECHO(%%~c
    ECHO(%%~d
    ECHO(%%~e
    ECHO(%%~f
    ECHO(%%~g
    ECHO(%%~h
    echo %holdingline%
)

GOTO :EOF

I used a file named q29639243.txt containing similar data for my testing. Produces u:\new.txt

edited Apr 15, 2015 at 6:04

answered Apr 15, 2015 at 0:04

Magoo

80.8k8 gold badges68 silver badges92 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Siddharth Swaminathan Over a year ago

Can the same be done using a file. I mean instead of using set command to enter value holdingline is there a way to read the file record into holdingline variable and do the same task?

Monacraft · Accepted Answer · 2015-04-14 23:59:11Z

2

This should do what you want it to:

@echo off
setlocal EnableDelayedExpansion
set holdingline=,Measure,,+ X,,,0,0
FOR /F "tokens=1,2,3,4,5,6,7,8 delims=," %%a IN ("%holdingline:,,=, ,%") DO (
    echo %%a
    echo %%b
    echo %%c
    echo %%d
    echo %%e
    echo %%f
    echo %%g
    echo %%h
    echo %holdingline%
)
pause

Replacing ,, with , , will cause it to set the middle variables to (space) and hence treat them like nothing. If you don't have anything between two , it will skip them and hence only 4 variables exist, leaving e-h blank

answered Apr 14, 2015 at 23:59

Monacraft

6,6502 gold badges20 silver badges30 bronze badges

1 Comment

Siddharth Swaminathan Over a year ago

Thanks. Your solution gets me closer. But it still doesn't treat the first null at the begining of the string and the 2 consecutive nulls as expected.

Collectives™ on Stack Overflow

Windows batch For Loop dropping empty strings to the end

2 Answers 2

1 Comment

1 Comment

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

1 Comment

Your Answer

Sign up or log in

Post as a guest

Linked

Related