My XML is
<row>
<entry>1.</entry>
<entry>foo</entry>
<entry>morefoo</entry>
</row>
<row>
<entry>2.</entry>
<entry>2foo</entry>
<entry>2morefoo</entry>
</row>
using XSLT, i'm trying to represent this information in a html table, and i want to have a Serial no. column.
How do i go about selecting the value of only the first 'entry' tag?
My XML is
<row> <entry>1.</entry> <entry>foo</entry> <entry>morefoo</entry> </row> <row> <entry>2.</entry> <entry>2foo</entry> <entry>2morefoo</entry> </row>
This is not wellformed XML document. A well-formed XML document must have exactly one top-level element. I will use the following (corrected to be well-formed) XML document:
<rows>
<row>
<entry>1.</entry>
<entry>foo</entry>
<entry>morefoo</entry>
</row>
<row>
<entry>2.</entry>
<entry>2foo</entry>
<entry>2morefoo</entry>
</row>
</rows>
How do i go about selecting the value of only the first 'entry' tag?
/*/row/entry[1]
The above selects the first entry element-child of every row element.
/*/row[1]/entry[1]
The above selects the first entry element-child of the first row element in the document.
/*/row[2]/entry[1]
The above selects the first entry element-child of the second row element in the document.
(//entry)[1]
The above selects the first entry element in the whole document.
//entry[1]
Note that this is different from the previous expression: this selects every entry element in the document, which is the first entry-child of its parent.
(//entry)[1] be used instead of just //entry[1]?(//entry)[1] isn't equivalent to //entry[1] and they both have their uses.In your XSLT you should have something like this:
<!-- matches the root (not specified in your post) -->
<xsl:template match="/">
<!-- at root level, make your table -->
<table>
<thead>.... </thead>
<tbody>
<!-- push the rows through, make sure the path is correct -->
<xsl:apply-templates select="path/to/row" />
</tbody>
</table>
</xsl:template>
<xsl:template match="row">
<!-- create the rows -->
<tr>
<!-- process first entry only, as you requested (why?) -->
<xsl:apply-templates select="entry[1]" mode="first"/>
<!-- process other entries -->
<xsl:apply-templates select="entry[position() > 1]" mode="other"/>
</tr>
</xsl:template>
<xsl:template match="entry" mode="first">
<!-- maybe you want the first cell to be treated specially, i.e. as row header -->
<th><xsl:value-of select="."/></th>
</xsl:template>
<xsl:template match="entry" mode="other">
<!-- the other cells -->
<td><xsl:value-of select="."/></td>
</xsl:template>
Note: the code above is not tested, use it as a template for your own real code and data.
Output would be something like the following:
<table>
<thead>....</thead>
<tbody>
<tr>
<th>1.</th>
<td>foo</td>
<td>morefoo</td>
</tr>
<tr>
<th>2.</th>
<td>2foo</td>
<td>2morefoo</td>
</tr>
<tr>....
</tbody>
</table>
//row/entry[1]
This will select all the entry tags that are the first child of the parent node.
The XSLT below will produce this table:
Serial No Name Description 1. foo morefoo 2. 2foo 2morefoo
Sample document:
<?xml version="1.0" encoding="utf-8"?>
<document>
<row>
<entry>1.</entry>
<entry>foo</entry>
<entry>morefoo</entry>
</row>
<row>
<entry>2.</entry>
<entry>2foo</entry>
<entry>2morefoo</entry>
</row>
</document>
XSLT:
<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="html" indent="yes"/>
<xsl:template match="/">
<html>
<head>
<title>Sample</title>
</head>
<body>
<table border="1">
<tr>
<th>Serial No</th>
<th>Name</th>
<th>Description</th>
</tr>
<xsl:apply-templates />
</table>
</body>
</html>
</xsl:template>
<xsl:template match="row">
<tr>
<xsl:for-each select="entry">
<td>
<xsl:value-of select="."/>
</td>
</xsl:for-each>
</tr>
</xsl:template>
</xsl:stylesheet>
