How can I dereference an array of arrays of arrays?

Question

I'm working on a Perl Dancer2 webapp and stumbled across the situation that I have an array that contains arrays that contain an array in position 2. I pass a reference to that array to a sub and then iterate over the array (that contains arrays).

When I try to get the innermost array inside a foreach() loop with @$$_[2], I get an error:

Not a SCALAR reference

I can easily work around this with:

my $ref = $$_[2];
print "@$ref\n";

but I wonder why the first approach doesn't work.

Have a look at my minimal example:

my @x = (["a", "b", [1, 2], "c"],
         ["x", "y", [8, 9], "z"]);
my $y = \@x;

foreach (@$y) {
#   print "@$$_[2]\n"; #produces error

    my $z = $$_[2];
    print "@$z\n"; #works
}

Any ideas what is going on here?

You have an answer. But I'd be very interested to know where you picked up that horrible referencing syntax. Most places only mention it in passing on their way to the more readable (and less confusing) $_->[2] syntax. — Dave Cross
– Dave Cross, Commented Nov 21, 2015 at 15:45
@DaveCross I think it was the first syntax I saw reading the perldoc about referencing: link and I found it kind of intuitive... personally, I don't find $$_[2] more or less confusing than $_->[2] but rather a matter of habit — mable
– mable, Commented Nov 21, 2015 at 23:22

choroba · Accepted Answer · 2015-11-20 17:24:47Z

5

You need curly braces:

@{$$_[2]}

or, more readable

@{ $_->[2] }

The original @$$_[2] is interpreted as

@{ $$_ }[2]

Cf.

use feature qw{ say postderef };

$_ = [['a'], ['b'], ['c', 'd']];
say for @{ $_->[2] };
say for $_->[2]->@*;

$_ = \[ @$_ ];
say @$_ for @{ $$_ }[2];
say @$_ for $_->$*->[2];

edited Nov 20, 2015 at 17:24

answered Nov 20, 2015 at 17:14

choroba

245k27 gold badges221 silver badges304 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

mable Over a year ago

Ok, got it! Thank you :)

Sobrique · Accepted Answer · 2015-11-20 17:13:44Z

0

Look at the -> operator. Likely the problem is the brackets. After all, when you say $$_[2] do you mean: ${$_}[2] or {$$_}[2].

Something like this is probably clearer (assuming you want the 1,2 and 8,9)

#!/usr/bin/env perl
use strict;
use warnings;
use Data::Dumper;

my @x = ( [ "a", "b", [ 1, 2 ], "c" ], 
          [ "x", "y", [ 8, 9 ], "z" ] );
my $y = \@x;

print Dumper $y;

foreach my $array_ref (@$y) {
    print Dumper $array_ref;
    my $z = $array_ref->[2];
    print "@$z\n";
}

answered Nov 20, 2015 at 17:13

Sobrique

53.6k8 gold badges63 silver badges107 bronze badges

Collectives™ on Stack Overflow

How can I dereference an array of arrays of arrays?

2 Answers 2

1 Comment

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related