I want to execute some for loops for every path provided in a variable. The echo !temp! works just fine, however the for commands below it won't work:
@echo off
setlocal enabledelayedexpansion
set paths=(C:\test C:\test2)
for %%p in %paths% do (
set temp=%%p
echo !temp!
for /r !temp! %%f in (*.h) do (echo %%f)
for /r !temp! %%g in (*.h *.cpp) do (echo %%g)
)
In all for commands syntax patterns:
FOR %%parameter IN (set) DO command
FOR /R [[drive:]path] %%parameter IN (set) DO command
FOR /D %%parameter IN (folder_set) DO command
FOR /L %%parameter IN (start,step,end) DO command
FOR /F ["options"] %%parameter IN (filenameset) DO command
FOR /F ["options"] %%parameter IN ("Text string to process") DO command
FOR /F ["options"] %%parameter IN ('command to process') DO command
all text preceding %%parameter should be known in the first parsing phase. Read How does the Windows Command Interpreter (CMD.EXE) parse scripts?.
However, next script should work as expected
@ECHO OFF
SETLOCAL EnableExtensions EnableDelayedExpansion
set "paths=(C:\test C:\test2)"
for %%p in %paths% do (
set "temp=%%~p"
echo !temp!
call :doit
)
rem skip procedure
goto :domore
:doit
for /r "%temp%" %%f in (*.h) do (echo %%f)
for /r "%temp%" %%g in (*.h *.cpp) do (echo %%g)
goto :eof
:domore
forcommand is handled before delayed expansion occurs, according to this post (see end of phase 2); you can overcome the problem in two ways: 1. change to the!temp!directory before the innerfor /Rloops and do not place!temp!after/R; 2. move thefor /Rloops to a subroutine, pass!temp!as an argument and use the%1expansion (seecall /?)...