Nested batch for loops

Question

The following nested for-loop drives me mad (on Windows 7):

@echo off
SetLocal EnableDelayedExpansion

set TESTDIRS=fast mid slow
set TD=src\test\resources\testsuite

for %%d in (%TESTDIRS%) do (
    set CTD=%TD%\%%d
    echo CTD: !CTD!
        REM Echos the expected path
    echo CTD: %CTD%
        REM Echos nothing -- understandable

    for /R !CTD! %%f in (*.fs) do (echo %%f)
        REM Echos nothing -- why?
    for /R src\test\resources\testsuite\fast %%f in (*.fs) do (echo %%f)
        REM Echos expected files
)

I tried various solutions involving disabling DelayedExpansion, call-statements and whatnot, but I never got the inner loop working. I know that I could replace the inner loop by a subroutine call, but there gotta be a way to make it work with nested loops.

I'm new to batch programming (though steeped in bash), and would have never in my entire life have intuited that variables set inside for loops require !! to express their values... — RonJohn
– RonJohn, Commented Feb 14, 2023 at 21:51

Malte Schwerhoff · Accepted Answer · 2015-05-04 07:33:49Z

38

Just to give an example of a nested loop that works:

@echo off
SetLocal

set B=alpha beta gamma
set A=eins zwo

FOR %%b in (%B%) do (
  FOR %%a in (%A% %%b) DO (
    echo %%b -^> %%a
  )
)

The output (at least on Windows 7) is

alpha -> eins
alpha -> zwo
alpha -> alpha
beta -> eins
beta -> zwo
beta -> beta
gamma -> eins
gamma -> zwo
gamma -> gamma

This supports jeb's observation that variable expansion in loops works if they occur inside parenthesis (even without delayed expansion).

edited May 4, 2015 at 7:33

answered Dec 8, 2010 at 8:29

Malte Schwerhoff

12.9k4 gold badges44 silver badges71 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

Juan Antonio Orozco Over a year ago

hi i used your example but it will print %%b instead of %%a in the last steep,i solved it by using just FOR %%a in (%A%) in the inner loop

Malte Schwerhoff Over a year ago

@JuanAntonioOrozco You might have observed the intended behaviour. I edited my answer to clarify what the loop should print.

Ryan Bemrose · Accepted Answer · 2015-06-17 02:36:05Z

17

Because nobody has mentioned it, here is the solution using batch subroutines and the CALL command.

@echo off

set TESTDIRS=fast mid slow
set TD=src\test\resources\testsuite

for %%d in (%TESTDIRS%) do call :process_testdir %%d
goto :eof

:process_testdir
set CTD=%TD%\%1
echo CTD: %CTD%
    REM Echos the expected path

for /R %CTD% %%f in (*.fs) do (echo %%f)
    REM Echos as expected

goto :eof

I know GOTO is not very popular, but batch files were originally designed to use labels for control flow. The parenthetized control structure syntax was added later, and this question is an example of where it breaks down. The problem lends itself well to batch subroutines.

edited Jun 17, 2015 at 2:36

answered Mar 4, 2015 at 19:50

Ryan Bemrose

9,3461 gold badge45 silver badges55 bronze badges

Comments

Ben Voigt · Accepted Answer · 2010-12-02 15:33:55Z

9

What if you used pushd !CTD! and popd, and let FOR /R default to using the current directory?

answered Dec 2, 2010 at 15:33

Ben Voigt

286k45 gold badges444 silver badges764 bronze badges

2 Comments

Malte Schwerhoff Over a year ago

I'll accept this solution since it solves the question in the context of my example. And it's really clever :-)

Algoman Over a year ago

This is a workaround that solves the specific problem differently. It doesn't explain how to correctly nest for-loops (i.e. doesn't answer the question). I want to nest for-loops with a different use-case in which this workaround doesn't solve the problem and came here via google search for "batch nested for loop". -1 from me.

Michel de Ruiter · Accepted Answer · 2016-09-08 10:22:19Z

6

It's not obvious! It's the special parsing of FOR!
A FOR command is parsed directly after the escape/special character phase (for detecting the parenthesis), but as a result you can't using delayed or %%var expansion as parameters.

FOR %%a in (%%%%B) do (
  FOR %%a in (1) DO ( <<< this %%a will not replaced with %%B
      echo %%a - shows 1, because %%a is the name of the inner variable
      echo %%B - doesn't work
  )
)

And also this can't work:

set chars=abc
FOR /F "delims=!chars!" %%N in (bla) DO ....

does not set a, b and c as delims, but !, c, h, a and r instead.

EDIT: Within the parentheses the delayed expansion does work as expected however:

set var=C:\temp
For %%a in (!var!) DO echo %%a

I would expect that you have to use a function to solve your problem.

edited Sep 8, 2016 at 10:22

Michel de Ruiter

8,1457 gold badges55 silver badges81 bronze badges

answered Dec 2, 2010 at 13:36

jeb

83.2k20 gold badges181 silver badges237 bronze badges

2 Comments

Malte Schwerhoff Over a year ago

Sorry, but I don't see how your reply helps me with my question since it only tells me what doesn't work. In addition, I already mentioned in my question that I am aware of the possibility of replacing the inner loop with a subroutine but my question was how to make the nested loop work.

jeb Over a year ago

Sorry, but I suppose you can only use the PUSHD solution from Ben Voigt. With expansion it seems to be impossible, because the path for the inner loop is expanded only one, at the beginning of the first parenthesis,

江明哲 · Accepted Answer · 2020-03-06 09:06:19Z

1

Quote Malte Schwerhoff's Answer

If you don't want to repeat B, you can simply add "if" statement

@echo off
SetLocal

set B=alpha beta gamma
set A=eins zwo

FOR %%b in (%B%) do (
  FOR %%a in (%A% %%b) DO (
    IF %%b NEQ %%a (
        echo %%b -^> %%a
    )
  )
)

output:

alpha -> eins
alpha -> zwo
beta -> eins
beta -> zwo
gamma -> eins
gamma -> zwo

answered Mar 6, 2020 at 9:06

江明哲

375 bronze badges

Comments

Stephan · Accepted Answer · 2020-06-27 09:38:07Z

0

According to FOR help, FOR /R "Walks the directory tree rooted at [drive:]path, executing the FOR statement in each directory of the tree."

What may be at issue is the word 'walk'. It seems to me that a walk doesn't occur until one takes the first step and if no step occurs then no walk occurs. Since in this case the walk begins in directory 'fast' and there are no subdirectories, no first step is possible.

However, if you change the second FOR to:

for /R !CTD!\..\ %%f in (*.fs) do (echo %%f)

then the result echoed is:

CTD: src\test\resources\testsuite\fast
CTD:
C:\FORTEST\src\test\resources\testsuite\fast\F1.fs
C:\FORTEST\src\test\resources\testsuite\mid\F2.fs
C:\FORTEST\src\test\resources\testsuite\slow\F3.fs
C:\FORTEST\src\test\resources\testsuite\fast\F1.fs
CTD: src\test\resources\testsuite\mid
CTD:
C:\FORTEST\src\test\resources\testsuite\fast\F1.fs
C:\FORTEST\src\test\resources\testsuite\mid\F2.fs
C:\FORTEST\src\test\resources\testsuite\slow\F3.fs
C:\FORTEST\src\test\resources\testsuite\fast\F1.fs
CTD: src\test\resources\testsuite\slow
CTD:
C:\FORTEST\src\test\resources\testsuite\fast\F1.fs
C:\FORTEST\src\test\resources\testsuite\mid\F2.fs
C:\FORTEST\src\test\resources\testsuite\slow\F3.fs
C:\FORTEST\src\test\resources\testsuite\fast\F1.fs

Is that what OP was looking 'FOR'? If so, it would be because now there is someplace to recurse from, that being the parent dir.

(Note: in this test the dirs fast, mid, slow contained one file each, F1.fs, F2.fs and F3.fs, respectively.)

edited Jun 27, 2020 at 9:38

Stephan

56.8k11 gold badges66 silver badges97 bronze badges

answered Jun 26, 2020 at 22:22

i YAM GzORM

11 bronze badge

1 Comment

John Neuhaus Over a year ago

This answer would include directories not in %TESTDIRS%. And as noted in the question, /R src\test\resources\testsuite\fast %%f works, which is the intended result of set CTD=%TD%\%%d, so the problem is not likely a misunderstanding of how the tree is being walked.

Collectives™ on Stack Overflow

Nested batch for loops

6 Answers 6

2 Comments

Comments

2 Comments

2 Comments

Comments

1 Comment

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

6 Answers 6

2 Comments

Comments

2 Comments

2 Comments

Comments

1 Comment

Your Answer

Sign up or log in

Post as a guest

Linked

Related