XSLT to concatenate multiple values into one tag

Question

For this XML -

<phoneContact>
    <firstName>XXXXX</firstName>
    <middleName>Y</middleName>
    <lastName>ZZZZZ</lastName>
    <generationalSuffix>Jr.</generationalSuffix>
    <phone>1234567890</phone>
</phoneContact>
<phoneContact>
    <firstName>AAAA</firstName>
    <middleName>B</middleName>
    <lastName>CCCCC</lastName>
    <phone>9876543210</phone>
    <!-- notice no generationalSuffix -->
</phoneContact>

and with this XSL -

<xsl:for-each select="phoneContact">
    <xsl:element name="phoneContact{position()}">
        <name>
            <xsl:if test="firstName">
                <xsl:value-of select="firstName"/>
                <xsl:text> </xsl:text> <!-- Add SPACE as a delimeter -->
            </xsl:if>
            <xsl:if test="middleName">
                <xsl:value-of select="middleName"/>
                <xsl:text> </xsl:text>
                </xsl:if>
            <xsl:if test="lastName">
                <xsl:value-of select="lastName"/>
                "<xsl:text> </xsl:text>
                </xsl:if>
            <xsl:if test="generationalSuffix">
                <xsl:value-of select="generationalSuffix"/>
                </xsl:if>
        </name>
        <phone><xsl:value-of select="phone"/></phone>
    </xsl:element>
</xsl:for-each>

I am using the XSL to -

have Phone Contacts named as different elements "phoneContact1", "phoneContact2", and so forth
get the name concatenated, with each name field separated by a SPACE.
There should be no leading or trailing spaces in the "name".

This is giving me the desired output, except for not being able to handle a trailing space when an element's value is NULL.

<phoneContact1>
    <name>XXXXX Y ZZZZZ Jr.</name>
    <phone>1234567890</phone>
</phoneContact1>
<phoneContact2>
    <name>AAAA B CCCCC </name> <!-- notice the TRAILING space -->
    <phone>9876543210</phone>
</phoneContact2>

Any suggestions, please? Thank you.

zx485 · Accepted Answer · 2016-03-03 20:28:14Z

3

An easy solution is using normalize-space on the concatenated values, this makes the stylesheet a lot more compacted:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:template match="/action">
    <xsl:for-each select="phoneContact">
      <xsl:element name="{concat('phoneContact',position())}">
        <name>
          <xsl:value-of select="normalize-space(concat(firstName,' ',middleName,' ',lastName,' ',generationalSuffix))" />
        </name>
        <phone><xsl:value-of select="phone"/></phone>
      </xsl:element>
    </xsl:for-each> 
  </xsl:template>
</xsl:stylesheet>

Result:

<?xml version="1.0"?>
<phoneContact1>
    <name>XXXXX Y ZZZZZ Jr.</name><phone>1234567890</phone>
</phoneContact1>
<phoneContact2>
    <name>AAAA B CCCCC</name><phone>9876543210</phone>
</phoneContact2>

answered Mar 3, 2016 at 20:28

zx485

29.1k28 gold badges55 silver badges65 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

mrigs13 Over a year ago

Thank you. This worked perfectly. I am an XSL noob, and will have to read up on normalize-space. Many thanks.

Collectives™ on Stack Overflow

XSLT to concatenate multiple values into one tag

1 Answer 1

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related