Generate an XML file in Delphi 10.1 and perform basic XML operations?

I normally don't like submitting a second answer but you didn't seem to follow what I said in my first one.

Below is a sample project which generates a new Xml file and adds a new Employee node to it every time you click the btnAdd button. The comments in the code should hopefully be sufficient to get you going.

Note that this project uses the Xml interfaces defined in the MSXML.Pas unit, it does not use the XmlDoc unit.

unit XmlGenerateu;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls, MSXML;

type
  TForm1 = class(TForm)
    Memo1: TMemo;
    edtName: TEdit;
    edtPlace: TEdit;
    btnAdd: TButton;
    procedure btnAddClick(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    procedure LoadXML;
    procedure SaveXML;
    procedure GenerateXML;
    function CreateEmployeeNode: IXmlDomElement;
  protected
  public
    XMLDoc : IXmlDomDocument;
    EmployeesNode : IXmlDomNode;
    NewEmployeeNode : IXmlDomNode;
  end;

var
  Form1: TForm1;

implementation

{$R *.DFM}

const
  scXmlTemplate =
    '<EmployeeDB>'#13#10
     + '  <Employees>'#13#10
     + '  </Employees>'#13#10
     + '</EmployeeDB>';

  scXmlFileName = 'C:\Temp\Employees.Xml';

procedure TForm1.btnAddClick(Sender: TObject);
begin
  NewEmployeeNode := CreateEmployeeNode;
  Memo1.Lines.Text := XmlDoc.xml;
  SaveXML;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  LoadXML;
end;

procedure TForm1.LoadXML;
begin
  //  If there is no existing Xml file create it from our Xml template
  //  and save it to disk
  if not FileExists(scXmlFileName) then begin
    Memo1.Lines.Text := scXmlTemplate;
    SaveXML;
  end;
  Memo1.Lines.LoadFromFile(scXmlFileName);

  //  Create the XmlDoc object
  XmlDoc := CoDomDocument.Create;
  //  Load it from Memo1
  Assert(XmlDoc.LoadXml(Memo1.Lines.Text));

  //  Find the Employees node
  EmployeesNode := XmlDoc.selectSingleNode('/EmployeeDB/Employees');
  //  Complain if we didn't find it
  Assert(EmployeesNode <> Nil);

end;

procedure TForm1.SaveXML;
begin
  Memo1.Lines.SaveToFile(scXmlFileName);
end;

function TForm1.CreateEmployeeNode : IXmlDomElement;
var
  EmployeeID : Integer;
  NameElement,
  PlaceElement : IXmlDomElement;
begin
  //  First, generate the ID for the new Employee
  EmployeeID :=  EmployeesNode.childNodes.length + 1;

  //  Next, get the XmlDoc to create a new Element
  Result := XmlDoc.createElement('Employee');

  //  Set the new Element's ID attribute
  Result.setAttribute('e.id', IntToStr(EmployeeID));

  //  Put the new Employee node at the end of the list of Employee nodes
  EmployeesNode.appendChild(Result);

  //  Finally, createt eName and ePlace children of the new Employee
  NameElement := XmlDoc.createElement('eName');
  NameElement.text := edtName.Text;
  Result.appendChild(NameElement);

  PlaceElement := XmlDoc.createElement('ePlace');
  PlaceElement.text := edtPlace.Text;
  Result.appendChild(PlaceElement);
end;

Update

You asked in a comment whether this could be done using TXmlDocument instead of the interfaces in the MSXML.Pas unit. I think that would be a good self-instructional exercise so I am not going to include the complete code to do it, but here are some hints.

There are some detail changes necessary, e.g. how to load the XMLDocument from Memo1, but the main change is in how to find the Employees nodes of the XML document. The simplest way to do this is to use an XPath query (see SelectSingleNode in the code above) but that involves using the same XML interfaces as are in MSXML.Pas and if you want to do that, you might as well avoid using TXmlDocument. If you want to avoid using XPath, then you can write two functions, which return the EmployeeDB and Employees nodes. These might look like this

function TForm1.GetEmployeeDBNode(XmlDoc : TXmlDocument) : IXmlNode;
begin
  Result := XmlDoc.DocumentElement;
  Assert(Result <> Nil);
  Assert(Result.NodeName = 'EmployeeDB');
end;

function TForm1.GetEmployeesNode(EmployeeDBNode : IXmlNode) : IXmlNode;
begin
  Result := EmployeeDBNode.ChildNodes.First;
  Assert(Result <> Nil);
  Assert(Result.NodeName = 'Employees');
end;

You could use these functions in an adapted version of CreateEmployeeNode to add the new Employee node by calling AddChild('Employee') on the node returned by GetEmployeesNode.

Btw, the need to write these functions, which assume XML document has a fixed structure, illustrate why using XPath is preferable, because it is easier to accommodate different XML structures, for example if the EmployeeDB were embedded in some larger Xml structure. Using XPath, this would require merely changing the XPath query string.