Making Perl's "specific declarations" as variable

Question

I was looking for some sort of solution if the following setup can be interpreted as formal declaration of the variables , if possible. What i have is :

my $str_1 = "{cow}" ;

my $str_2 = "{cow}{black}{tasty_milk}";

what i want is :

(Based on above variable string is it possible to initialize a hash directly, something like :)

my %hash=();

$hash."*some operator* on $str_i"  = 'Initialized' ;

This "some operator" should make $hash to recognize as hash as it was declared earlier. i.e Input specific hash initialization.

PS: I don't want to write a function that will work on the string and get all information to initialize the hash.

See also Creating hash of hash dynamically in perl and Read config hash-like data into perl hash — Håkon Hægland
– Håkon Hægland, Commented Mar 28, 2017 at 11:28
I'm afraid your question is clear as mud. What is the expected output? — jcaron
– jcaron, Commented Mar 28, 2017 at 11:30

ikegami · Accepted Answer · 2017-03-29 15:01:39Z

4

Say you had the following input instead:

my @path = qw( cow black tasty_milk );

Then you can use the following:

use Data::Diver qw( DiveVal );

DiveVal(\%hash, map \$_, @path) = 'value';

So, with Data::Diver, we get:

use Data::Diver qw( DiveVal );

$str =~ /^(?:\{\w+\})+\z/
   or die("Unrecognized format");

my @path = $str =~ /(\w+)/g;
DiveVal(\%hash, map \$_, @path) = 'value';

Without a module:

sub dive_val :lvalue { my $p = \shift;  $p = \( $$p->{$_} ) for @_;  $$p }

$str =~ /^(?:\{\w+\})+\z/
   or die("Unrecognized format");

my @path = $str =~ /(\w+)/g;
dive_val(\%hash, @path) = 'value';

edited Mar 29, 2017 at 15:01

answered Mar 28, 2017 at 12:43

ikegami

391k17 gold badges291 silver badges555 bronze badges

Sign up to request clarification or add additional context in comments.

8 Comments

ikegami Over a year ago

@reinierpost, It validates the input, parses the input, then sets the hash element. How is that not obvious?

reinierpost Over a year ago

It is obvious that it tries to do something like that, but with the question not being stated clearly and your code being extremely terse without any comments, I have trouble understanding what is going on and above all why, and I'm someone who has been working with Perl code for 20 years.

ikegami Over a year ago

Which one is it? Is what it does obvious, or do you have a hard time understanding what it does?

reinierpost Over a year ago

It isn't obvious what it does, and it isn't obvious that it is what jordan vj wants.

ikegami Over a year ago

@reinierpost, You are gravely mistaken. It's very obvious that a check that results in die("Unrecognized format") checks if the input is in a recognized format. I can't believe I have to tell you that if you've ever programmed before (in any language).

|

mkHun · Accepted Answer · 2017-03-28 16:22:53Z

0

Try the following with anonymous hash

use Data::Dumper;
use warnings; 
use strict;

my $str_2 = "{cow}{black}{tasty_milk}";
my %hash;
my $ref =\%hash;
my $val;
my $lp = () = $str_2=~m/\}/g; #count the number of }
my $i = 1;
while($str_2=~m/\{(\w+)\}/g)
{
    $val = $1;

    last if ($lp == $i); 

    $ref->{$val} = {}; #make the anonymous hash        

    $ref = $ref->{$val};   #add the data into anonymous hash

    $i++;

}
$ref->{$val} = "value"; #add the last value

print Dumper \%hash;

answered Mar 28, 2017 at 16:22

mkHun

5,9479 gold badges45 silver badges96 bronze badges

3 Comments

ikegami Over a year ago

By the way,

my $ref =\%hash; my $val; my $lp = () = $str_2=~m/\}/g; my $i = 1; while($str_2=~m/\{(\w+)\}/g) {     $val = $1;      last if ($lp == $i);       $ref->{$val} = {};      $ref = $ref->{$val};      $i++;  } $ref->{$val} = "value";

simplifies to my $p = \\%hash; $p = \( $$p->{$1} ) while $str_2 =~ /\{(\w+)\}/g; $$p = "value";

mkHun Over a year ago

@ikegami It is very amazing. I have tried to know your trick but I can't please shall you explain this.? :)

ikegami Over a year ago

The trick is to add a layer of indirection. More about this here and here

Collectives™ on Stack Overflow

Making Perl's "specific declarations" as variable

2 Answers 2

8 Comments

3 Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

8 Comments

3 Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related