Perl regex match multiple instances of a pattern and replace

Question

I have a string that looks like this:

abc[1,2,3].something.here,foo[10,6,34].somethingelse.here,def[1,2].another

I want to split this string into an array that consists of:

abc[1,2,3].something.here
foo[10,6,34].somethingelse.here
def[1,2].another

But splitting on the comment won't work so my next idea is to first replace the commas that reside between the square brackets with something else so I can split on the comma, then replace after the fact.

I've tried a few approaches with little success.. Any suggestions?

Eugene Yarmash · Accepted Answer · 2011-03-18 13:38:16Z

4

You can use look-ahead assertion in the pattern:

my $s = "abc[1,2,3].something.here,foo[10,6,34].somethingelse.here,def[1,2].another";
my @a = split /,(?=\w+\[)/, $s;

answered Mar 18, 2011 at 13:38

Eugene Yarmash

152k44 gold badges346 silver badges391 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

gdanko Over a year ago

Excellent, I will research look-ahead! Thanks!

gdanko Over a year ago

Adding host1.something.here will break this regex. Where would be a good reference for this look-ahead assertion?

Bill Ruppert · Accepted Answer · 2011-03-18 14:10:09Z

1

When things get that complex, I like the parser approach.

#!/usr/bin/perl
use strict;
use warnings;

my $statement  =  "abc[1,2,3].something.here,foo[10,6,34].somethingelse.here,def[1,2].another";

my $index      = qr/\[(?:\d+)(?:,\d+)*\]/;
my $variable   = qr/\w+$index?/;
my $expression = qr/$variable(?:\.$variable)*/;

my @expressions = ($statement =~ /($expression)/g);

print "$_\n" for @expressions;

answered Mar 18, 2011 at 14:10

Bill Ruppert

9,0567 gold badges30 silver badges44 bronze badges

Comments

Henley Wing Chiu · Accepted Answer · 2011-03-18 13:41:09Z

0

Iterate through the characters in the string like this (pseudocode):

found_closing_bracket = 0;
buffer = ''
array = []

foreach c in str:

   if c == ']'
      found_closing_bracket = 1

   if c == ',' && found_closing_bracket == 1
     push(array, buffer)
     buffer = ''
     found_closing_bracket = 0

   else
     buffer = buffer + c

Sure, you could use regular expressions, but personally I rather aim for a simpler solution even if it's more hackish. Regular expressions are a pain to read sometimes.

answered Mar 18, 2011 at 13:41

Henley Wing Chiu

22.8k37 gold badges134 silver badges216 bronze badges

Comments

reinierpost · Accepted Answer · 2011-03-18 13:56:33Z

0

An alternative to eugene y's answer:

my $s = "abc[1,2,3].something.here,foo[10,6,34].somethingelse.here,def[1,2].another";
my @a = ($s =~ /[^,]+\[[\d,]*\]/g);
print join("\n", @a,"")

answered Mar 18, 2011 at 13:56

reinierpost

8,6671 gold badge43 silver badges73 bronze badges

Comments

bvr · Accepted Answer · 2011-03-18 14:42:17Z

0

This question gave me excuse to take a look at Regexp::Grammars I wanted for some time. Following snippet works for your input:

use Regexp::Grammars;
use Data::Dump qw(dd);

my $input
    = 'abc[1,2,3].something.here,foo[10,6,34].somethingelse.here,def[1,2].another';

my $re = qr{
    <[tokens]> ** (,)  # comma separated tokens

    <rule: tokens>     <.token>*
    <rule: token>      \w+ | [.] | <bracketed>
    <rule: bracketed>  \[ <.token> ** (,) \]
}x;

dd $/{tokens}
    if $input =~ $re;

# prints
# [
#   "abc[1,2,3].something.here",
#   "foo[10,6,34].somethingelse.here",
#   "def[1,2].another",
# ]

answered Mar 18, 2011 at 14:42

bvr

9,69725 silver badges28 bronze badges

Collectives™ on Stack Overflow

Perl regex match multiple instances of a pattern and replace

5 Answers 5

2 Comments

Comments

Comments

Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

5 Answers 5

2 Comments

Comments

Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related