How to sort string array by length?

Question

So, I want to sort array of strings by length (longer strings goes first) and if length is the same, then sort alphabetically. This is what is got so far:

uses
  System.Generics.Defaults
  , System.Types
  , System.Generics.Collections
  ;

procedure TForm2.FormCreate(Sender: TObject);
var
  _SortMe: TStringDynArray;
begin
  _SortMe := TStringDynArray.Create('abc', 'zwq', 'Long', 'longer');

  TArray.Sort<string>(_SortMe, TDelegatedComparer<string>.Construct(
    function(const Left, Right: string): Integer
    begin
      Result := CompareText(Left, Right);
    end));
end;

Expected result: longer, Long, abc, zwq

Where in your code do you compare lengths?

David Heffernan
– David Heffernan

2017-12-30 10:08:39 +00:00
Commented Dec 30, 2017 at 10:08 — David Heffernan
– David Heffernan, Commented Dec 30, 2017 at 10:08

Sebastian Proske · Accepted Answer · 2017-12-30 09:50:49Z

5

Adjusting your anonymous function:

function(const Left, Right: string): Integer
    begin
      //Compare by Length, reversed as longest shall come first
      Result := CompareValue(Right.Length, Left.Length);
      if Result = EqualsValue then
        Result := CompareText(Left, Right);
    end));

You'll need to add System.Math and System.SysUtils to your uses.

answered Dec 30, 2017 at 9:50

Sebastian Proske

8,4432 gold badges30 silver badges38 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Arnaud Bouchez · Accepted Answer · 2017-12-30 09:52:03Z

2

I would have used a TStringList for this...

Any way, just customize the comparison function:

  TArray.Sort<string>(_SortMe, TDelegatedComparer<string>.Construct(
    function(const Left, Right: string): Integer
    begin
      Result := length(Right) - length(Left); // compare by decreasing length
      if Result = 0 then
        Result := CompareText(Left, Right);  // compare alphabetically
    end));

answered Dec 30, 2017 at 9:52

Arnaud Bouchez

43.1k3 gold badges78 silver badges165 bronze badges

Collectives™ on Stack Overflow

How to sort string array by length?

2 Answers 2

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related