Defining and acessing variables in a local environment

Question

After quite a while of studying CL and practising as a hobby in different small projects, I still have some blank areas on my personal CL map. Recently, I had a number of functions using all the same let construct and I thought of writing a macro which makes the code more concise:

(defmacro with-context (&body body)
   `(let ((context (make-array 4 :element-type 'fixnum
                                 :initial-contents '(0 1 2 3))))
     ,@body))

So that I can later define functions like (just as a minimal example):

(defun test-a ()
  (with-context
    (setf (aref context 3)
          (+ (aref context 0) (aref context 1)))
    context))

Now I was wondering if I could shorten the (aref context n) expressions with a macro/function like (context n).

(defun context (n)
  (aref context n))

But the variable context is unknown at compile time, of course. I just don't know if I have a case of basic misunderstanding here or how I could tell lisp what I actually want. So, my question is basically if it is possible and if it is a good idea.

Rainer Joswig · Accepted Answer · 2019-06-26 13:13:53Z

4

What's wrong with a local function?

(defmacro with-context (&body body)
  `(let ((context (make-array 4 :initial-contents '(0 1 2 3))))
     (flet ((context (n)
              (aref context n)))
       ,@body)))

Setting, too:

(defmacro with-context (&body body)
  `(let ((context (make-array 4 :initial-contents '(0 1 2 3))))
     (flet ((context (n)
              (aref context n))
            ((setf context) (new n)
              (setf (aref context n) new)))
       ,@body)))

edited Jun 26, 2019 at 13:13

answered Jun 26, 2019 at 12:27

Rainer Joswig

140k11 gold badges230 silver badges357 bronze badges

Sign up to request clarification or add additional context in comments.

4 Comments

Svante Over a year ago

This wouldn't be a place you could setf, no?

Rainer Joswig Over a year ago

@Svante: added now

Martin Buchmann Over a year ago

Thanks for clarification. Just for my understanding: If if have a main function using with-contextand other function defined outside of main which want to use context I end up in a situation similar to the one discussed in another question, recently and should consider another strategy, I guess.

Martin Buchmann Over a year ago

@RainerJoswig I will try ;-)

Svante · Accepted Answer · 2019-06-26 11:51:23Z

3

You could put a macrolet into your macro expansion:

(defmacro with-context (&body body)
  (with-gensyms (i)
    `(let ((context (make-array 4 …)))
       (macrolet ((context (,i)
                    `(aref context ,,i)))
         ,@body))))

Some personal notes:

I dislike anaphoric macros, so I'd generally let the user define the name for the context. That would feel strange with the context macrolet though. I'd then maybe come to the conclusion that all I want is a make-standard-context function and keep using let. I think this is in line with the general guideline “be conventional”.

edited Jun 26, 2019 at 11:51

answered Jun 26, 2019 at 11:04

Svante

51.8k11 gold badges84 silver badges127 bronze badges

1 Comment

Martin Buchmann Over a year ago

I understand your point and will consider another solution. Nevertheless, I think there is a , missing before `(aref context ,i)

Collectives™ on Stack Overflow

Defining and acessing variables in a local environment

2 Answers 2

4 Comments

1 Comment

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

4 Comments

1 Comment

Your Answer

Sign up or log in

Post as a guest

Linked

Related