Passing arguments containing spaces from one script to another in Perl

Question

I am trying to pass arguments from one Perl script to another. Some of the arguments contain spaces.

I am reading in a comma-delimited text file and splitting each line on the comma.

my ($jockey, $racecourse, $racenum, $hnamenum, $trainer, $TDRating, $PRO) = split(/,/, $line);

The data in the comma-delimited text file look as follows:

AARON LYNCH,WARRNAMBOOL,RACE 1,DAREBIN (8),ERIC MUSGROVE,B,1

When I print out each variable, from the parent script, they look fine (as above).

print "$jockey\n";
print "$racecourse\n";
print "$racenum\n";
print "$hnamenum\n";
print "$trainer\n";
print "$TDRating\n";
print "$PRO\n";           

AARON LYNCH
WARRNAMBOOL
RACE 1
DAREBIN (8)
ERIC MUSGROVE
B
1

When I pass the arguments to the child script (as follows), the arguments are passed incorrectly.

system("perl \"$bindir\\narrative4.pl\" $jockey $racecourse $racenum $hnamenum $trainer $TDRating $PRO");

AARON
LYNCH
WARRNAMBOOL
RACE
1
DAREBIN
(8)

As you can see, $ARGV[0] becomes AARON, $ARGV[1] becomes LYNCH, $ARGV[2] becomes WARRNAMBOOL, and so on.

I have investigated adding quotes to the arguments using qq, quotemeta and Win32::ShellQuote, unfortunately, even if I pass qq{"$jockey"}, the quotes are still stripped before they reach the child script, so they must be protected in some way.

I not sure if either of the aforementioned solutions is the correct but I'm happy to be corrected.

I'd appreciate any suggestions. Thanks in advance.

Note: I am running this using Strawberry Perl on a Windows 10 PC. Note2: I purposely left out use strict; & use warnings; in these examples.

Parent Script

use Cwd;
$dir = getcwd;
$bin = "bin"; $bindir = "$dir/$bin";

$infile = "FINAL-SORTED-JOCKEY-RIDES-FILE.list";

open (INFILE, "<$infile") or die "Could not open $infile $!\n";

while (<INFILE>)
{
   $line = $_;

   chomp($line);

   my ($jockey, $racecourse, $racenum, $hnamenum, $trainer, $TDRating, $PRO) = split(/,/, $line); 

   print "$jockey\n";
   print "$racecourse\n";
   print "$racenum\n";
   print "$hnamenum\n";
   print "$trainer\n";
   print "$TDRating\n";
   print "$PRO\n";            

   system("perl \"$bindir\\narrative4.pl\" $jockey $racecourse $racenum $hnamenum $trainer $TDRating $PRO");

   sleep (1);
}
close INFILE;

exit;

Child Script

$passedjockey = $ARGV[0];
$passedracecourse = $ARGV[1];
$passedracenum = $ARGV[2];
$passedhnamenum = $ARGV[3];
$passedtrainer = $ARGV[4];
$passedTDRating = $ARGV[5];
$passedPRO = $ARGV[6];

print "$passedjockey\n";
print "$passedracecourse\n";
print "$passedracenum\n";
print "$passedhnamenum\n";
print "$passedtrainer\n";
print "$passedTDRating\n";
print "$passedPRO\n\n";

Use the list version of system?

Shawn
– Shawn

2020-06-02 07:15:39 +00:00
Commented Jun 2, 2020 at 7:15 — Shawn
– Shawn, Commented Jun 2, 2020 at 7:15

zdim · Accepted Answer · 2020-06-02 08:20:57Z

7

That whole double-quoted string that is passed to system is first evaluated and thus all variables are interpolated -- so the intended multi-word arguments become merely words in a list. So in the end the string has a command to run with individual words as arguments.

Then, even if you figure out how to stick which quotes in there just right, so to keep those multi-word arguments "together," there's still a chance of a shell being invoked, in which case those arguments again get broken up into words before being passed to the program.

Instead of all this use the LIST form of system. The first argument is then the name of the program that will be directly executed without a shell (see docs for some details on that), and the remaining arguments are passed as they are to that program.

parent

use warnings;
use strict;
use feature 'say';

my @args = ('first words', 'another', 'two more', 'final'); 

my $prog = 'print_args.pl';

system($prog, @args) == 0  
    or die "Error w/ system($prog, @args): $!";

and the invoked print_args.pl

use warnings;
use strict;
use feature 'say';

say for @ARGV;

The @ARGV contains arguments passed to the program at invocation. There's more that can be done to inspect the error, see docs and links in them.^†

By what you show you indeed don't need a shell and the LIST form is generally easy to recommend as a basic way to use system, when the shell isn't needed. If you were to need shell's capabilities for something in that command then you'd have to figure out how to protect those spaces.

^† And then there are modules for running external programs that are far better than system & Co. From ease-of-use to features and power: IPC::System::Simple, Capture::Tiny, IPC::Run3, IPC::Run.

edited Jun 2, 2020 at 8:20

answered Jun 2, 2020 at 7:35

zdim

67.2k5 gold badges59 silver badges87 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

Billy J Over a year ago

Perfect! Thank you so much @zdim And thank you for the detailed explanation and additional info regarding running external programs, etc. I will investigate further. All the best!

zdim Over a year ago

@BillyJ Very glad if it helps :). A nice thing about using those modules is that there is nothing to it -- look at synopsis in the linked docs and that's all that need be done; one line of code. And one gets a better thing. So I absolutely recommend that. Take care :)

Collectives™ on Stack Overflow

Passing arguments containing spaces from one script to another in Perl

1 Answer 1

2 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

2 Comments

Your Answer

Sign up or log in

Post as a guest

Related