Get Image from SQL using Listbox to picturebox VB

Remove the picture retrieval from the Form.Load. We have selected all the data in the GetDataFromSql function. The magic happens in the ListBox1.SelectedIndexChanged method.

The SelectedIndexChanged will occur as a result of the code in the Form.Load and every time the selection changes. When we bind the the list box to to binding source the entire row is added as a DataRowView. We can use this to get the data in the Image column. First check if the field is null. Next cast to a byte array. Take the byte array and pass it to the constructor of a MemoryStream. Streams need to be disposed so it is in a Using block. Finally the stream can be assigned to the Image property of the PictureBox.

Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    Dim dt = GetDataFromSql()
    Dim BndSrc As New BindingSource()
    BndSrc.DataSource = dt
    ListBox1.DisplayMember = "ItemName"
    ListBox1.DataSource = BndSrc
    TextBox1.DataBindings.Add("Text", BndSrc, "ItemID")
    TextBox2.DataBindings.Add("Text", BndSrc, "ItemName")
    TextBox3.DataBindings.Add("Text", BndSrc, "Details")
End Sub

Private Function GetDataFromSql() As DataTable
    Dim dt As New DataTable
    Using connection As New SqlConnection("Data Source=WXCQSDQSD\SQLEXPRESS;Initial Catalog=food;Integrated Security = True"),
        cmd As New SqlCommand("select * FROM Items", connection)
        connection.Open()
        Using reader = cmd.ExecuteReader
            dt.Load(reader)
        End Using
    End Using
    Return dt
End Function

Private Sub ListBox1_SelectedIndexChanged(sender As Object, e As EventArgs) Handles ListBox1.SelectedIndexChanged
    Dim row = DirectCast(ListBox1.SelectedItem, DataRowView)
    If row("Image") IsNot Nothing Then
        Dim b() As Byte = DirectCast(row("Image"), Byte()) '< ------ Cast the field to a Byte array.
        Using ms As New System.IO.MemoryStream(b)
            PictureBox1.Image = System.Drawing.Image.FromStream(ms)
        End Using
    Else
        PictureBox1.Image = Nothing
    End If
End Sub

EDIT

I switched the code over to a database I have available for testing. Even though it is not your database, I am sure you will be able to follow the code.

Here is the schema of my database.

The main difference is I moved the DataTable to a class level variable so it can be seen from all methods. I changed the GetDataFromSql to a Sub. It adds the data to the class level DataTable (Bounddt). The AddItem method first gets the Byte() from a file. The row is added to the DataTable with an Object array with elements that match the DataTable.

Private Bounddt As New DataTable

Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    GetDataFromSql()
    Dim BndSrc As New BindingSource()
    BndSrc.DataSource = Bounddt
    ListBox1.DisplayMember = "CustomerID"
    ListBox1.DataSource = BndSrc
    TextBox1.DataBindings.Add("Text", BndSrc, "CustomerID")
    TextBox2.DataBindings.Add("Text", BndSrc, "CustomerName")
End Sub

Private Sub GetDataFromSql() 
    Using connection As New SqlConnection("Data Source=****;Initial Catalog='Small Database';Integrated Security=True;Connect Timeout=30;Encrypt=False;TrustServerCertificate=False;ApplicationIntent=ReadWrite;MultiSubnetFailover=False"),
    cmd As New SqlCommand("select * FROM Sales.Customer", connection)
        connection.Open()
        Using reader = cmd.ExecuteReader
            Bounddt.Load(reader)
        End Using
    End Using
    'Return dt
End Sub

Private Sub ListBox1_SelectedIndexChanged(sender As Object, e As EventArgs) Handles ListBox1.SelectedIndexChanged
    Dim row = DirectCast(ListBox1.SelectedItem, DataRowView)
    If row("Picture") IsNot Nothing Then
        Dim b() As Byte = DirectCast(row("Picture"), Byte()) '< ------ Cast the field to a Byte array.
        Using ms As New System.IO.MemoryStream(b)
            PictureBox1.Image = System.Drawing.Image.FromStream(ms)
        End Using
    Else
        PictureBox1.Image = Nothing
    End If
End Sub
Private Sub AddItem()
    Dim picture = GetByteArr("C:\Users\maryo\OneDrive\Documents\Graphics\Animals\squirrel.png")
    Bounddt.Rows.Add({5, "George", 74, 62, "George", picture})
End Sub

Private Function GetByteArr(path As String) As Byte()
    Dim img = Image.FromFile(path)
    Dim arr As Byte()
    Dim imgFor As Imaging.ImageFormat
    Dim extension = path.Substring(path.LastIndexOf(".") + 1)
    'There is a longer list of formats available in ImageFormat
    Select Case extension
        Case "png"
            imgFor = Imaging.ImageFormat.Png
        Case "jpg", "jpeg"
            imgFor = Imaging.ImageFormat.Jpeg
        Case "bmp"
            imgFor = Imaging.ImageFormat.Bmp
        Case Else
            MessageBox.Show("Not a valid image format")
            Return Nothing
    End Select
    Using ms As New MemoryStream
        img.Save(ms, imgFor)
        arr = ms.ToArray
    End Using
    Return arr
End Function
Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
    AddItem()
End Sub