Using variables in a for loop

Question

I understand the magic of the setlocal enabledelayedexpansion; this brought me one step further but I am still not completely happy. I am now able to assign the filename to a !loop variable!, but I fail to use that variable subseqently. I try to get the filename without the extension. There must be something else that I am unaware of.

This is my coding now:

::process all files in directory
setlocal enabledelayedexpansion

for %%f in (C:\windows\*.ico) do (

    echo F=%%f
    set myname=%%f
    echo.N=!myname!
    call :strlen myLen "!myname!"
    echo.myLen=!myLen!

    set /A L=myLen-3 + 1
    set str=!myname!
    echo.str1=!str! L=!L!
    set str=!str:~0,!L! !    <-Remove extension from filename
    echo.str2=!str!          <-This does not work!

)

Here is the output of my call :

 F=C:\windows\AnyWeb Print.ico
 N=C:\windows\AnyWeb Print.ico
 Strlen C:\windows\AnyWeb Print.ico
 myLen=25
 str1=C:\windows\AnyWeb Print.ico L=23
 str2=L       <--- what went wrong ????

Honestly, learn powershell. Then you won't have to keep on doing what I like to call cmd gymnastics, twisting yourself in knots trying to bend a basically deficient language to your needs :-) — paxdiablo
– paxdiablo, Commented Jan 15, 2022 at 13:28
Why don't you use ~-modifiers of the for meta-variable, like %%~Nf to get the base name and %%~Xf to get the extension, for instance? N. B.: The Windows command prompt is NOT a DOS prompt! — aschipfl
– aschipfl, Commented Jan 15, 2022 at 14:04

jeb · Accepted Answer · 2022-01-15 13:44:37Z

1

The problem is the line

set str=!str:~0,!L! !    <-Remove extension from filename

The exclamation marks are used from left to right, you get two parts

set str=!str:~0,! and L! !

This could be solved by using a different form of expansion, like FOR-loop-parameter, like

for %%X in (!L!) DO set str=!str:~0,%%X!

But in your case there exist a much simpler solution

for %%C in (C:\windows\*.ico) do (

  set myname=%%C
  set name_without_extension=%%~nC
  echo Name=!myname!
  echo Only Name=!name_without_extension!
)

answered Jan 15, 2022 at 13:44

jeb

83.2k20 gold badges181 silver badges237 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Magoo · Accepted Answer · 2022-01-15 16:45:35Z

0

In the general case,

CALL set str=%%str:~0,!L!%%

This executes a subshell where the command set str=%str:~0,{the value of L}% is executed.

But please note that not all filenames have a 3-character extension; the for modifiers are a better bet for that application. This method is a general-purpose get the first L characters of a string where L's instantaneous value is required.

answered Jan 15, 2022 at 16:45

Magoo

80.8k8 gold badges68 silver badges92 bronze badges

Collectives™ on Stack Overflow

Using variables in a for loop

2 Answers 2

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related