Call variable in for loop - BATCH

Question

I would like to know if it's possible or other ways to get this:

 @echo off
 setlocal enableDelayedExpansion
 SET loopcount=3

 SET variable1=test1
 SET variable2=test2
 SET variable3=test3

 for /l %%x in (1, 1, %loopcount%) do {
      echo %variable%%x%
 }

As you can see in echo, I want to get the value of variable1 which is test1 and so on... Is there any workaround on this? Thank you.

or even: For /L %%x in (1 1 3)Do For /F "Tokens=2* Delims==" %%G in (' Set "Variable%%x" 2^> nul ')Do Echo(%%G — T3RR0R
– T3RR0R, Commented Mar 16, 2021 at 16:09

Compo · Accepted Answer · 2021-03-16 12:04:06Z

1

The best way to perform your task, is to use delayed expansion.

In your example you already enabled it, but didn't use it. A delayed variable is enclosed within ! characters, as opposed to % characters.

Example:

@Echo Off
SetLocal EnableExtensions EnableDelayedExpansion
Set "loopcount=3"

Set "variable1=test1"
Set "variable2=test2"
Set "variable3=test3"

For /L %%G In (1,1,%loopcount%) Do (
    Echo(!variable%%G!
)

However, you should wherever possible, you should only enable delayed expansion, when needed:

@Echo Off
SetLocal EnableExtensions DisableDelayedExpansion
Set "loopcount=3"

Set "variable1=test1"
Set "variable2=test2"
Set "variable3=test3"

For /L %%G In (1,1,%loopcount%) Do (
    SetLocal EnableDelayedExpansion
    Echo(!variable%%G!
    EndLocal
)

answered Mar 16, 2021 at 12:04

Compo

39k5 gold badges32 silver badges46 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

lit Over a year ago

@DockerJava-Guy, if this is the best answer, please select the check mark to indicate that to other people. This is how SO works.

Collectives™ on Stack Overflow

Call variable in for loop - BATCH

1 Answer 1

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related