Raku Actions Predicated on Parse Success?

Question

Is there a way to configure Raku actions to only execute after a parse has completed successfully? For example, the program below outputs "Jane is telling us her age....", even with malformed input.

grammar Foo {
  rule TOP { <name> is \d+ }
  token name { [Anne | Jane] { say "$/ is telling us her age...."; } }
}

say so Foo.parse('Anne is 100');  # True
say so Foo.parse('Jane is Leaf'); # False

wamba · Accepted Answer · 2024-07-18 21:10:12Z

You could move the code block to the rule TOP;

grammar Foo {
    rule TOP { <name> is \d+ { say  "$/<name> is telling us her age...."  } }
    token name { [Anne | Jane]  }
}

say so Foo.parse('Anne is 100');
say so Foo.parse('Jane is Leaf');

Anne is telling us her age....
True
False

using the routines make and made;

grammar Foo {
    rule TOP { <name> is \d+ }
    token name { [Anne | Jane]  { make  "$/ is telling us her age...."  } }
}

say Foo.parse('Anne is 100').<name>.made;
say Foo.parse('Jane is Leaf').<name>.made;

Anne is telling us her age....
Nil

or their combination.

grammar Foo {
    rule TOP { <name> is \d+  { say  $/<name>.made } }
    token name { [Anne | Jane]  { make  "$/ is telling us her age...."  } }
}

say so Foo.parse('Anne is 100');
say so Foo.parse('Jane is Leaf');

Anne is telling us her age....
True
False

Remember that for more complex problems, you can explore using Actions.

Collectives™ on Stack Overflow

Raku Actions Predicated on Parse Success?

1 Answer 1

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

Comments

Your Answer

Sign up or log in

Post as a guest

Related